How can I include studies with missing data in meta forestplot

[Simon Turner]

Hi all,
It's very common in the types of meta-analyses that I perform that some studies do not provide meta-analysable data.
We often use forestplots to help summarise both the pooled effect AND the actual data we have access to.
I cannot find a way using the meta forestplot command to include blank lines for studies with missing data.
Maybe I'm missing something?
This would be super useful.
Cheers,
Simon.

Attached code has a simple example, I would like the output to have Study C included (obviously with missing data where the data is missing)

* Data is missing from one study, but forestplot only shows those which have data
* 1. Create example data with one missing study
clear
input str20 study es se str20 data_summary
"Study A" 0.5 0.1 "n, mean, sd"
"Study B" 0.7 0.2 "SMD calculated"
"Study C" .   .  "no data for analysis" // This study has no data
"Study D" 0.4 0.1 "n, mean, sd"
end

* 2. Set the meta-analysis data
meta set es se, studylabel(study)

* 3. Create the forest plot
meta forestplot _id data_summary _plot _es _ci

[Andrew Musau]

I don't think there is such an option, except including such studies in the graph's notes. Whether the idea is sound given the space constraints, I have doubts.

* Data is missing from one study, but forestplot only shows those which have data
* 1. Create example data with one missing study
clear
input str20 study es se str20 data_summary
"Study A" 0.5 0.1 "n, mean, sd"
"Study B" 0.7 0.2 "SMD calculated"
"Study C" .   .  "no data for analysis" // This study has no data
"Study D" 0.4 0.1 "n, mean, sd"
"Study E" .   .  "no data for analysis" // This study has no data
end


 * 2. Set the meta-analysis data
meta set es se, studylabel(study)


* 3. Create the forest plot
replace study= "`=uchar(28)'  `=uchar(28)'" + study if missing(es)
levelsof study if missing(es), local(missing)
meta forestplot _id data_summary _plot _es _ci, note("  {bf:Missing Data}" " " `missing')

[David Fisher]

Hi Simon Turner
Apologies for the late response. This can be done with the user-written metan command, as follows:

* Data is missing from one study, but forestplot only shows those which have data
* 1. Create example data with one missing study
clear
input str20 study es se str20 data_summary
"Study A" 0.5 0.1 "n, mean, sd"
"Study B" 0.7 0.2 "SMD calculated"
"Study C" .   .  "no data for analysis" // This study has no data
"Study D" 0.4 0.1 "n, mean, sd"
end

label variable data_summary "Notes"
format %-1s study
metan es se, label(namevar=study) keeporder forestplot(lcols(data_summary) xlabel(0(.2)1) astext(70))