Code to add conditional Y distributions (at selected values of X) to a scatter-plot

[Bruce Weaver]

Does anyone have code to add conditional Y distributions at selected values of X to scatter-plots? My main priority is getting the idealized normal distributions conforming to the IID N(0, sigma²) assumption, like this...



But if I could plot empirical distributions too, that would be great.

Thanks,
Bruce

[ericmelse]

Dear Bruce, I am sorry to not have an answer for you, but, could you include the code that replicates your example?

[Maarten Buis]

sysuse auto, clear
set scheme s1mono

// the basic graph
gen ub = (_n-61)/20 in 1/61
gen lb = - ub
gen x = normalden(ub)
twoway rarea ub lb x

// now apply it to a regression model
reg price c.mpg##c.mpg

// get the standard deviation
local sd = e(rmse)

// get the means
margins, at(mpg=(15(5)35))
forvalues i = 1/5 {
    local m`i' = el(r(table),1,`i')
}

// prepare the xs
local i = 1
foreach x of numlist 15(5)45 {
    gen x`i++' = x + `x'
}

// prepare the ys
local gr = ""
forvalues i = 1/5 {
    gen ub`i' = `m`i'' + ub*`sd'
    gen lb`i' = `m`i'' + lb*`sd'
    local gr = "`gr' rarea ub`i' lb`i' x`i', astyle(p3area) ||"
}

// the graph
predict yhat
twoway `gr' scatter price mpg, msymbol(oh) || ///
       line yhat mpg, lpattern(solid) sort legend(off)

// We need the "stretch" the normal graphs a bit
// lets start with a factor 4
local i = 1
foreach x of numlist 15(5)45 {
    replace x`i++' = x*4 + `x'
}
twoway `gr' scatter price mpg, msymbol(oh) mcolor(black) || ///
       line yhat mpg, lpattern(solid) sort legend(off)  ///
       ylab(,angle(0) format(%9.0gc))

[Nick Cox]

For conditional distributions of data, see also dotplot (official command) and stripplot from SSC.

[Bruce Weaver]

Many thanks, Maarten Buis and Nick Cox. ericmelse, I did not create the graph I showed in #1. It is from a SAS webpage.

Cheers,
Bruce