Standardized variable by year

[salma ktat]

Hi everyone,
I want to standardize a variable within each year. So I used

egen zCSR= std( CSR),by( year)

but I got this message from stata: egen ... std() may not be combined with by.
So, is there another option to use for this purpose knowing that my variable is a categorical variable (I don't know if this information is important, however)
Thanks in advance and sorry, my question may be so simple!

[Clyde Schechter]

So you have to write a loop:

gen zCSR = .
tempvar junk
levelsof year, local(years)
foreach y of local years {
    egen `junk' =  std(CSR) if year == `y'
    replace zCSR = `junk' if year == `y'
    drop `junk'
}

And if you want to check that it was done correctly, you can see the results with -tabstat zCSR, by(year) statistics(mean sd)-.

[salma ktat]

Thanks Clyde, this is working well, the means and sd are good values. But, I just have a question, why did you use 2 commands

 
 egen `junk' =  std(CSR) if year == `y'     replace zCSR = `junk' if year == `y'

Why don't we use just one command which is:
egen `zCSR' = std(CSR) if year == `y' Thanks again.

[Nick Cox]

I would not write a loop here.

egen mean = mean(CSR), by(year)
egen z = sd(CSR), by(year)
replace z = (CSR - mean) / z

[Clyde Schechter]

To answer Salma's question about why I used two commands instead of one is, that this was necessitated by the loop. Had I just used the single command -egen zCSR = std(CSR) if year == `y'- is that the second time through the loop, zCSR would already exist and -egen-, wanting to create a new variable would complain and stop.

Avoiding this complication is one advantage of Nick's approach over mine.

[Nick Cox]

It seems an anomaly that std() doesn't support operations by: or by(). The idea makes perfect sense.

[Mohamed Khalil]

Nick, how this code changes if I would like to calculate std() for the variable for each industry (sic) and year (year)?

Thank you

[Nick Cox]

Just change what you feed to by().

By (sic) I take it you mean (SIC). See also https://en.wikipedia.org/wiki/Sic

[Mohamed Khalil]

Thank you Nick
By (sic), I have meant industry code. My question was about calculating the standardised value of a variable grouping by both (sic) and (year).

Thank you

[Nick Cox]

Sure, and I answered you. Just change what you feed to by(). So, the option will be by(sic year) (assuming that those are your variable names).

[Mohamed Khalil]

Thank you Nick.