Survey adjustment for t tests and difference in proportions

[Carisa Klemeyer]

I am working with complex survey data from two different time points: 2009 (at the end of a nutrition intervention) and 2011 (to look at how well the program and its effects were sustained). Mothers were the secondary sampling units, individual health centers were the PSUs, and geographic blocks were strata. We have calculated various indicators (including nutrition status) and are comparing these indicators across the two time periods.

Can the t tests and tests for difference in proportions be adjusted to account for the survey design? My chief concern is that the 2009 and 2011 samples were drawn independently from one another, so the PSUs are not the same. Does that matter?

Also, I have read that there is no svy:ttest option, but that I can use svy: regress or svy: mean to run a survey-adjusted t test. Is that correct? For the difference in proportions, is there a svy: ptest option, or another way to survey-adjust the a test for difference in proportions?

Thanks so much,
Carisa Klemeyer

[Steve Samuels]

For "t-tests" of survey data (comparison of two means) see:http://http://www.ats.ucla.edu/stat/...q/svyttest.htm, which you could have found by typing in Stata "search survey ttest". So the answer to your question:

Also, I have read that there is no svy:ttest option, but that I can use svy: regress or svy: mean to run a survey-adjusted t test. Is that correct?

is "Yes".

Proportions are means of 0-1 variables. Therefore the procedures for comparing means will also compare proportions. However confidence intervals for the proportions themselves may extend below zero or above one. svy: prop and svy: tabulate specifically estimate proportions. However only svy: tabulate will keep confidence intervals between zero and one (CIs are computed on the logistic scale, then coverted to the probability scale). To compare the proportions, use lincom after either command.

Some examples for proportions:

sysuse auto, clear
gen mkr = substr(make,1,2) /*artificial PSU */
svyset mkr [pw = turn]
gen hiprice = price>8000  /* outcome */

svy: prop hiprice, over(foreign) coeflegend /* get parameter names */
lincom _b[_prop_2:Foreign]-_b[_prop_2:Domestic]

svy: reg hiprice ibn.foreign,nocons
svy: reg hiprice foreign

/* recommended */
svy: tab foreign hiprice, row se ci
lincom _b[p12]-_b[p22]