Sorting box plots

[Konrad Zdeb]

Hi All,

I would like to sort a set of box plots by interquartile range or some other measure corresponding to dispersion. I am currently using simple code below:

graph box var1- var10, asyvars showyvars yvaroptions(label(angle(ninety) labsize(vsmall))) legend(off)

[Robert Wells]

The option that sorts the box in the order you want is a option of over (sort(varname). while yvaroptions support some over() options, not apparently this one.

The problem is that your data appears to be wide as opposed to long which makes the calculation of a variable reflecting the variation difficult as it would be the same for each of the observations.

If your doing a small and quick job, perhaps just hardcode the varlist in the order of the measure, otherwise for a larger job i would convert to long (reshape) and use the over option.

Sorry it is not the most useful solution

[Konrad Zdeb]

If your doing a small and quick job, perhaps just hardcode the varlist in the order of the measure, otherwise for a larger job i would convert to long (reshape) and use the over option.

Robert,

thank you for showing the interest, this is what I did in this case.

[Nick Cox]

There is absolutely no need to reshape as you can always automate the ordering of the variables. Here I use foreach as something more generalisable than would be a forval over 1 to 10 exploiting the structure of your variable names.

 
gen name = ""
gen iqr = . 
local i = 0 
qui foreach v of var var1-var10 { 
    local ++i  
    su `v', detail 
    replace name = "`v'" in `i' 
    replace iqr = r(p75) - r(p25) in `i' 
} 

sort iqr  

forval j = 1/`i' { 
    local names `names' `=name[`i']' 
} 

graph box `names'

The assumption is that you have fewer variables for which you want box plots than observations. At worst, set obs fixes the last.

[Konrad Zdeb]

Nick, this is excellent. Thank you very much.

[Chen Samulsion]

I have the same need and fortunately come across this thread. Nick's solution is fine, however, in the last line but two, the code should be typed as `=name[`j']'.

There is absolutely no need to reshape as you can always automate the ordering of the variables. Here I use foreach as something more generalisable than would be a forval over 1 to 10 exploiting the structure of your variable names.

gen name = ""
gen iqr = .
local i = 0
qui foreach v of var var1-var10 {
local ++i
su `v', detail
replace name = "`v'" in `i'
replace iqr = r(p75) - r(p25) in `i'
}

sort iqr

forval j = 1/`i' {
local names `names' `=name[`i']'
}

graph box `names'

The assumption is that you have fewer variables for which you want box plots than observations. At worst, set obs fixes the last.

[Nick Cox]

Correct. Thanks for the fix.