Suppress surrounding line of a legend

[Dusan Petrovic]

Hello statalisters,

I've been struggling with this for a moment already and don't know what to do...

I've generated this kdenisty plot and I want to have no line around the legend. I thought that by using : legend( region(lwidth(none) margin(none)) the problem would be gone, but it won't.

Here is my code (and my figure) :

twoway kdensity wucaf_u24_mg if sex==1 & index==1, lwidth(*2.5) || kdensity wucaf_u24_mg if sex==2 & index==1, name(ucaf_sex) ///
legend(ring(0) pos(2) textfirst cols(1) region(lwidth(none) margin(none)) order(1 "Males" 2 "Females")) lwidth(*2.5) subtitle("By sex")

[Dusan Petrovic]

The figure

[Stephen Jenkins]

Try the following instead:

 legend( region(lstyle(none)) )

And if you want a full black/weight lean scheme, also add

graphregion(color(white))  scheme(s2mono)

Please note the use of CODE delimiters to display code and output. This makes material much easier to read by comparison with yours, I submit. See the FAQ on how to use CODE delimiters

[Svend Juul]

legend(...region(lpattern(blank))...)

[Dusan Petrovic]

Great, thanks a lot

[Dusan Petrovic]

BTW I bought your book Svend, it's great

[Dusan Petrovic]

I'm sorry guys, but your propositions don't really work :

neither :

legend( region(lstyle(none)) )

nor :

 legend(...region(lpattern(blank))...)

[Stephen Jenkins]

"don't really work " is a very unhelpful description for anyone who considers assisting you! (See the FAQ on this.) Show us exactly what you typed into Stata (the whole graphics command) and exactly what you got back -- as the FAQ advises.

[Dusan Petrovic]

Well, none of the codes that Svend nor you proposed do result in suppressing the lines around the legend... Neither the use of both of them...

twoway kdensity wucaf_u24_mg if sex==1 & index==1, lwidth(*2.5) || kdensity wucaf_u24_mg if sex==2 & index==1, name(ucaf_sex) ///
 legend(ring(0) pos(3) textfirst cols(1) region(lpattern(blank) lwidth(none) lstyle(none)) order(1 "Males" 2 "Females")) lwidth(*2.5) subtitle("By sex")

Thank you for your kind help

[Svend Juul]

You mean, it did not solve the problem? On your graph, which was created using the s2color scheme, I can see a faint line around the legend area. I could even reconstruct it:

set scheme s2color
sysuse auto, clear
twoway (scatter mpg weight if foreign==0)(scatter mpg weight if foreign==1) ///
, legend(region(lpattern(blank)) ring(0) pos(2))

This happens with the s2 schemes, not with the s1 schemes. Removing region(lpattern(blank)) leads to a distinct line around the legend.

Is it the faint line around the legend that you dislike. In that case, I don't know any other remedy than swithching sceme to, e.g., s1color, lean1, or lean2.

[Phil Clayton]

How about this?

set scheme s2color
sysuse auto, clear
twoway (scatter mpg weight if foreign==0)(scatter mpg weight if foreign==1) ///
, legend(region(color(none)) ring(0) pos(2))

[Svend Juul]

Phil's suggestion may create what Dusan wants. However, the background in the legend box is transparent, making the gridline visible behind the text. Perhaps this is a better solution:

legend(region(color(white))...)

[Dusan Petrovic]

Hello,

At last! Thank you all!