POLS with time and country fixed effects

[Dung Delime]

Hi everyone, I’ve received some reviewer feedback regarding my methodology. Specifically, I used Pooled OLS with Driscoll-Kraay standard errors (xtscc), but I also included time and country fixed effects in the model. Am I mistaken in calling this Pooled OLS? Technically, since I’ve included those fixed effects, has it effectively become a Fixed Effects (FE) model rather than POLS?

[Andrew Musau]

It depends on the observation level, which you do not mention. If your observations are at the country level, including country and time fixed effects results in a two-way fixed effects (TWFE) model. With firm- or individual-level panel data, including country dummies and time fixed effects can be described as Pooled OLS with dummies, although the country dummies absorb cross-country differences and the time fixed effects absorb common shocks. Some might describe this as a one-way time fixed effects model with country-level controls, but technically it is not a standard one-way FE model where in this case you would have firm- or individual-fixed effects and no time effects.

[Dung Delime]

Thank you for the clarification. To provide more context: my research uses panel data (65 countries over 4 years).

[Manh Hoang Ba]

Hi Dung,

I've read your two posts on this same topic, and I understand that the issue lies only in the terminology, and the reviewer seems a bit conservative on this point.
The two-way effects model has the form:
y_it = X_it*beta + u_i + v_t + e_it (1)
If u_i and v_t are correlated with X, they are classified as fixed effects (FE), and (1) is called a two-way fixed effects model (TWFE).

To estimate the parameters of interest (beta), one can use several different methods based on OLS:

1. Pooled OLS on original data + individual/time dummies (reg + dummies)
2. Pooled OLS on transformed data (demeaned data) (xtreg, areg, reghdfe)

These two methods differ mainly in computational performance, especially when the number of cross-sectional units becomes large, as in labor/firm panel data. In my opinion, you are absolutely right to call your results OLS + dummies. However, the term TWFE is more commonly used, while when referring to Pooled OLS, it is usually associated with a model where u_i = v_t = 0.

The main point I want to warn you about concerns your use of the xtscc command to calculate the Driscoll-Kraay Standard Error (DKSE).

• First, DKSE is designed for large T panels, which is probably not suitable for your case.
• Next, the fe option only adjusts in OWFE, not TWFE (your case).
• Finally, DK-OWFE (xtscc y x, fe lag()) and DK-OLS+dummies (xtscc y x i.id, lag()) give different standard errors because DK-OWFE does not adjust for degrees of freedom when calculating the standard error.

The code below illustrates this:

webuse abdata, clear
qui {
reg n k w i.id
estimates store ols_dum
xtreg n k w, fe
estimates store fe
xtscc n k w i.id, lag(1)
estimates store dk_ols_dum
xtscc n k w, fe lag(1)
estimates store dk_fe
}
esttab ols_dum fe dk_ols_dum dk_fe, b(7) se(7) ///
    keep(k w) mtit("OLS+dum" "OWFE" "DK-OLS+dum" "DK_FE" )
    
* adjust degree of fredom in DK-FE
qui {
mat b=e(b)
mat V=e(V)
mat V = V * (e(N) - 3) / (e(N) - e(N_g)-2)
ereturn post b V, dep(n)
}
ereturn display

. esttab ols_dum fe dk_ols_dum dk_fe, b(7) se(7) ///
>         keep(k w) mtit("OLS+dum" "OWFE" "DK-OLS+dum" "DK_FE" )

----------------------------------------------------------------------------
                      (1)             (2)             (3)             (4)   
                  OLS+dum            OWFE      DK-OLS+dum           DK_FE   
----------------------------------------------------------------------------
k               0.6403675***    0.6403675***    0.6403675***    0.6403675***
              (0.0201417)     (0.0201417)     (0.0411264)     (0.0382450)   

w              -0.3677740***   -0.3677740***   -0.3677740      -0.3677740   
              (0.0523227)     (0.0523227)     (0.1785959)     (0.1660832)   
----------------------------------------------------------------------------
N                    1031            1031            1031            1031   
----------------------------------------------------------------------------
Standard errors in parentheses
* p<0.05, ** p<0.01, *** p<0.001

.         
. * adjust degree of fredom in DK-FE
. qui {

. ereturn display
------------------------------------------------------------------------------
           n | Coefficient  Std. err.      z    P>|z|     [95% conf. interval]
-------------+----------------------------------------------------------------
           k |   .6403675   .0411264    15.57   0.000     .5597613    .7209737
           w |   -.367774   .1785959    -2.06   0.039    -.7178156   -.0177325
       _cons |   2.494684   .5558052     4.49   0.000     1.405325    3.584042
------------------------------------------------------------------------------