Changing order of the variable in table created by "Collect"

[Richard Thomas Boylan]

I am wondering how I change the order of the variable in table created by "Collect"
Here is an example.
sysuse auto.dta
collect, tag(model[(1)]): reg price mpg weight
collect, tag(model[(2)]): reg price foreign weight
collect dims
collect levelsof model
collect layout (colname#result[_r_b]) (model)

The order of the variables in the table is: mpg weight foreign.
How do I change the order in the table to: mpg foreign weight?

[Evgeny Saburov]

You can simply spell out the levels of the colname dimension explicitly, in an order you want to display:

collect levelsof colname
collect layout (colname[mpg foreign weight _cons]#result[_r_b] ) (model)

[Andrew Musau]

Also see

help collect style autolevels

sysuse auto.dta
collect clear
collect, tag(model[(1)]): reg price mpg weight
collect, tag(model[(2)]): reg price foreign weight
collect layout (colname#result[_r_b]) (model)
collect style autolevels colname mpg foreign weight _cons
collect preview

Res.:

. collect layout (colname#result[_r_b]) (model)

Collection: default
      Rows: colname#result[_r_b]
   Columns: model
   Table 1: 8 x 2

-----------------------------------
              |       (1)       (2)
--------------+--------------------
Mileage (mpg) |                    
  Coefficient | -49.51222          
Weight (lbs.) |                    
  Coefficient |  1.746559  3.320737
Car origin    |                    
  Coefficient |            3637.001
Intercept     |                    
  Coefficient |  1946.069 -4942.844
-----------------------------------

. 
. collect style autolevels colname mpg foreign weight _cons

. 
. collect preview

-----------------------------------
              |       (1)       (2)
--------------+--------------------
Mileage (mpg) |                    
  Coefficient | -49.51222          
Car origin    |                    
  Coefficient |            3637.001
Weight (lbs.) |                    
  Coefficient |  1.746559  3.320737
Intercept     |                    
  Coefficient |  1946.069 -4942.844
-----------------------------------

.

[Richard Thomas Boylan]

Thank you so much Egenvy and Andrew!