Multiple coefficient plots in one single graph.

[chintu red]

Hello everyone,
I have 20 items ranging and a price as my dependent variable. With independent variable and lagged variables in the regression model. And I do have some interaction variables too in the regression, I want to replicate the attached graph for my analysis in Stata.

I have tried the following code.

xtset panelid date

reghdfe price var L1.var L2.var L3.var if item_new==1, absorb(district month year) vce(cluster district)

matrix b = e(b)
matrix V = e(V)

local lags var L1.var L2.var L3.var
*dataset
clear
set obs 12
gen lag = 1 + _n - 1
gen beta = .
gen lb = .
gen ub = .

local i = 1
foreach var of local lags {
scalar bval = b[1, "`var'"]
scalar se = sqrt(V[`i', `i'])
replace beta = bval in `i'
replace lb = bval - 1.96*se in `i'
replace ub = bval + 1.96*se in `i'
local ++i
}


twoway ///
(rarea ub lb lag, color(maroon%20))
(line beta lag, lcolor(maroon) lwidth(medium)), ///
xtitle("Lag (months)") ytitle("β (ln price)") ///
yline(0, lpattern(solid) lcolor(black) lwidth(medium)) ///
title("temperature effects on price: Item 1")"

However, this is for one item only, I want to have the similar graphs for all the items from 1 to 20, can someone please let me know how to do it? It would be of great help. I have taken help of AI but unable to do it.

Thanks.

[Maarten Buis]

To make such a graph you typically use the by() option:

// prepare example data
clear all
webuse nlswork2, clear

gen byte wave:wave_lb = 1 if year == 68
replace  wave         = 2 if year == 69
replace  wave         = 3 if year == 70
replace  wave         = 4 if year == 71
replace  wave         = 5 if year == 72
replace  wave         = 6 if year == 73
replace  wave         = 7 if year == 75
replace  wave         = 8 if year == 77
replace  wave         = 9 if year == 78

label define wave_lb 1 "1968" ///
                     2 "1969" ///
                     3 "1970" ///
                     4 "1971" ///
                     5 "1972" ///
                     6 "1973" ///
                     7 "1975" ///
                     8 "1977" ///
                     9 "1978" 

xtset idcode wave

// estimate an example model
xtreg ln_wage L(0/5).wks_ue L(0/5).hours L(0/5).msp L(0/5).south, fe

// store the coefficients in a different frame
frame create tograph
frame change tograph

// svmat2 allows you to also store the rownames as a string variable
net install svmat2, ///
   from("https://raw.githubusercontent.com/maartenteaches/svmat2/main")

// r(table) contains the coefficients and confidence intervals (and other things)
matrix res = r(table)
// it is convenient to transpose (flip rows and collumns) that table
matrix res = res'
// store that matrix as a dataset
svmat2 res, names(col) rownames(var)

// the variable name includes the lag operator (e.g. L2.south)
// we want to split the operator (L2) from the variable name (south)
split var, parse(".") gen(op)
rename op1 operator
rename op2 variable

// the non-lagged variable name end up in the operator variable rather than the
// variable variable
gen tochange = missing(variable)
replace variable = operator if tochange
replace operator = "" if tochange
drop tochange

// We want to keep variables that are lagged
gen lag = regex(operator, "^L")
gen order = _n
bysort variable (order) : replace lag = sum(lag)
bysort variable (order) : replace lag = lag[_N] >=1
drop if lag == 0
drop lag
sort order
drop order

// We want to find the lag
gen lag = subinstr(operator, "L", "", 1)
replace lag = "0" if missing(operator)
replace lag = "1" if operator == "L"
destring lag, replace

// now we can graph
twoway rarea ll ul lag, astyle(ci) ||         ///
       line b lag ,                           ///
       by(variable, note("") yrescale ixaxes) ///
       xlab(0/5) ytitle(effect)
       
// now we can go back to the original dataset
frame change default

// if we want to change the graph, we can go back to 
// the dataset with coefficients       
frame change tograph

// we can change back and forth between datasets however many times we want

[Felix Bittmann]

Thanks Maarten for providing the nice example. However, I think this can be done slightly quicker, using coefplot and estout (both from SSC). Here the example for the first variable, hours.

eststo M1: xtreg ln_wage L(0/5).wks_ue L(0/5).hours L(0/5).msp L(0/5).south, fe
coefplot M1, keep(*hours*) vert recast(line) title("Hours") ///
    ciopts(recast(rarea) color(gs12%30)) ///
    coeflabels(hours="0" L.hours="1" L2.hours="2" L3.hours="3" L4.hours="4" L5.hours="5") ///
    yline(0) xtitle("lag")