Percentage bars

[Hans Rahr]

I want a bar chart to show the percentage of observations with each of nine different values (0 to 8) in four groups of patients.
This code shows the number of patients (i e, frequency) with each of these values in each of the four groups (see attached fig):

 graph bar (count), over(value) over(Pt_group) bargap(10)

This code shows the percentage (see attached fig):

 graph bar, over(value) over(Pt_group)

But it is obvious that the percentage is calculated with the entire patient cohort (i e, all four groups) as the denominator.

How do I get the percentage within each patient group?

I have tried the graphics menu and selected the option "Graph of percent of frequencies within categories", but that is apparently not what I get?

Thanks for any advice

[ericmelse]

You can consider for more flexibility the user community contributed package catplot that provides this with many more relevant options:

ssc install catplot, replace
which catplot
h catplot

[Nick Cox]

This may help. Most of the code here consists of setting up a data example, but you have the data

clear 
set obs 100 
gen Pt_group = ceil(_n/25)
set seed 31459 
gen value = runiformint(0, 8)
capture set scheme stcolor 
tab value Pt_group, column 

graph bar (percent), over(value) by(Pt_group) blabel(bar)

[Hans Rahr]

Thank you very much, Nick, but that resulted in four separate graphs (see enclosure). I would very much like a graph like the examples shown (one panel). I can also add a percent option after the over options in the original code and get the correct percentages, but then the axis labels (0-8) disappear. I would very much like to keep the axis labels.

[Nick Cox]

Noting now #2, here is extra code producing the same graph:

clear 
set obs 100 
gen Pt_group = ceil(_n/25)
set seed 31459 
gen value = runiformint(0, 8)
capture set scheme stcolor 
graph bar (percent), over(value) by(Pt_group) blabel(bar) name(G1, replace)

tab value Pt_group, column 

catplot, recast(bar) over(value) by(Pt_group) percent(Pt_group) blabel(bar) name(G2, replace)

For real data if you wanted the bar labels at all, extra formatting would be a good idea.

[Nick Cox]

#4 Well, as Eric Melse commented, you could look at the help to find other possibilities. Here is one:

 catplot, recast(bar) over(value, gap(*0.5)) over(Pt_group) percent(Pt_group) name(G3, replace)

I have omitted the bar labels. 36 bars in a row is less likely to make that a good choice.

[Nick Cox]

And, depending a little on what it is graded 0 to 8, a histogram may also be competitive:

histogram value, by(Pt_group, row(1)) discrete horizontal percent barw(0.8) bfcolor(stc1*0.4) yla(0/8) blcolor(stc1)

[Hans Rahr]

Thanks a lot, Nick and Eric

This produced the desired result (se enclosure):

 catplot, recast(bar) over(value) over(Pt_group) percent(Pt_group) name(G2, replace)

Have a nice evening
Hans