Reshape long with multiple cases

[Anne Todd]

Let's say I have a bunch of variable names that start with either j1 or j2: j1move j2move j1clean j2clean j1out j2out, and so on. Is there an efficient way to write a loop that would rename all of those variables such that the "j#" gets moved from the beginning of the variable name to the end of the variable name?

[Andrew Musau]

Note that variable names cannot start with numbers.

rename j1* *j1

See

help varlist

[Nick Cox]

I don't know what kind of reshape long you're warming up to.

This works for your question about rename, and there is probably a shorter way to do it.

clear
set obs 1

foreach v in j1move j2move j1clean j2clean j1out j2out {
    gen `v' = 42
}

* you start here
unab prefixes : *move  
local prefixes : subinstr local prefixes "move" "", all

foreach pre of local prefixes {
    rename (`pre'*)  (*`pre')
}

ds

[Anne Todd]

Thanks Nick Cox . How could I also drop the "j" after moving it to the end, such that the end of each var name would simply just have a "1" or "2"?

[Andrew Musau]

As usual, Nick is correct! You don't need to rename with stubs at the beginning, just reference them using @.

clear
set obs 1
foreach v in j1move j2move j1clean j2clean j1out j2out {
    gen `v' = 42
}
gen obsno=1
list
reshape long @move @clean @out, i(obsno) j(which) string
list

Res.:

. list

     +-------------------------------------------------------------+
     | j1move   j2move   j1clean   j2clean   j1out   j2out   obsno |
     |-------------------------------------------------------------|
  1. |     42       42        42        42      42      42       1 |
     +-------------------------------------------------------------+

. 
. reshape long @move @clean @out, i(obsno) j(which) string
(j = j1 j2)

Data                               Wide   ->   Long
-----------------------------------------------------------------------------
Number of observations                1   ->   2           
Number of variables                   7   ->   5           
j variable (2 values)                     ->   which
xij variables:
                          j1move j2move   ->   move
                        j1clean j2clean   ->   clean
                            j1out j2out   ->   out
-----------------------------------------------------------------------------

. 
. list

     +------------------------------------+
     | obsno   which   move   clean   out |
     |------------------------------------|
  1. |     1      j1     42      42    42 |
  2. |     1      j2     42      42    42 |
     +------------------------------------+


​​​​​​​

[Nick Cox]

Isn't that a different question from #1? Either way, the loop should now be something like

foreach pre of local prefixes { 
    local pre2 = substr("`pre'", 2, .)
    rename (`pre'*)  (*`pre2')
}

[Anne Todd]

Thanks Andrew Musau , now to extend to my actual data and eventual reshape, how could I do that with the below example? If I use the below code taken from yours, I get the error 'variable which contains all missing values'

reshape long @change @change_who, i(person_id date) j(which)

* Example generated by -dataex-. For more info, type help dataex
clear
input byte person_id str9 date byte(j1change j2change) str6(j1change_who j2change_who)
1 "2017Aug15" 0 . ""       ""      
1 "2017Aug16" 0 . ""       ""      
1 "2017Aug17" 0 . ""       ""      
1 "2017Aug18" 1 . "Me"     ""      
1 "2017Aug19" 1 . "Friend" ""      
1 "2017Aug20" 0 . ""       ""      
1 "2017Aug21" 0 . ""       ""      
1 "2017Aug22" 0 . ""       ""      
2 "2017Aug15" 0 0 ""       ""      
2 "2017Aug16" 0 0 ""       ""      
2 "2017Aug17" 0 0 ""       ""      
2 "2017Aug18" 0 0 ""       ""      
2 "2017Aug19" 0 1 ""       ""      
2 "2017Aug20" 0 0 ""       ""      
2 "2017Aug21" 0 0 ""       ""      
2 "2017Aug22" 1 0 "Me"     ""      
3 "2017Aug15" 0 . ""       ""      
3 "2017Aug16" 1 . "Friend" ""      
3 "2017Aug17" 0 . ""       ""      
3 "2017Aug18" 0 . ""       ""      
3 "2017Aug19" 1 . "Friend" ""      
3 "2017Aug20" 0 . ""       ""      
3 "2017Aug21" 0 . ""       ""      
3 "2017Aug22" 1 . "Me"     ""      
4 "2017Aug15" 1 0 "Me"     ""      
4 "2017Aug16" 1 0 "Me"     ""      
4 "2017Aug17" 1 0 "Me"     ""      
4 "2017Aug18" 1 0 "Me"     ""      
4 "2017Aug19" 0 0 ""       ""      
4 "2017Aug20" 0 0 ""       ""      
4 "2017Aug21" 0 1 ""       "Friend"
4 "2017Aug22" 0 0 ""       ""      
end

[Nick Cox]

#7 I think you need the string option. See help reshape.