Meta-analysis - subgroup analysis

[Ange Tj]

Hi all,

I used the metan command and would like to determine the p value for subgroup difference

The result generated is as follows

Tests of subgroup effect size = 0:
subgroupA z = 20.708 p=0.000
subgroupB z=30.601 p=0.000
Overall z=36.944 p=0.000

Just wanted to check - is the overall p value for between subgroup difference?

Thanks in advance

[Tiago Pereira]

Ange, hi. Can you show us more details?

[Ange Tj]

Hi Tiago, more details below. I was not expecting p value to be significant so wanted to clarify whether overall p value is for between subgroup - thanks. No significant heterogeneity between subgroups.

--------------------------------------------------------------------
Subgroup and Trial | Effect [95% Conf. Interval] % Weight
---------------------+----------------------------------------------
SubgroupA
TrialA | 69.000 55.500 80.500 7.55
TrialB | 71.000 60.000 80.000 11.80
TrialC | 39.000 24.000 56.000 4.61
TrialD | 75.700 56.300 84.700 5.85

Subgroup, IV | 66.468 60.177 72.760 29.82
---------------------+----------------------------------------------
SubgroupB
TrialA | 63.400 55.400 70.800 19.91
TrialB | 58.000 52.000 65.000 27.94
TrialC | 62.000 44.000 77.000 4.34
TrialD | 74.600 62.400 78.600 17.99

Subgroup, IV | 64.035 59.934 68.136 70.18
---------------------+----------------------------------------------
Overall, IV | 64.761 61.325 68.197 100.00
--------------------------------------------------------------------

Tests of subgroup effect size = 0:
subgroupA z = 20.708 p = 0.000
subgroupB z = 30.601 p = 0.000
Overall z = 36.944 p = 0.000

[Tiago Pereira]

The test results do not display an assessment of differences in subgroup estimates. The presented z values are for the tests that investigate whether the summary effect sizes for subgroup A, B, or the overall analysis differ from zero.

[Belinda Njiro]

Hi. I have a question about doing subgroup analysis using the "metan" command. My outcome is in prevalence, and I am able to do subgroup analysis and obtain a forest plot for each variable independently using "by". However, I want to combine all the subgroup analyses in a single figure. I know this is possible with metasummarize but when I use it with metan command I get this error

name: too many specified
Error in metan.ProcessLabels

Here is the code I used for two variables (cat_country and who_region)

metan p se, lcols(Author) xlabel(0 10 20 30 40 50 60 70 80 90 100) textsize(340) keepall random b2title()dp(1) scale(0.3) xsize(10) ysize(10) by(cat_country who_region)

I would appreciate your help. Thanks in advance.

[David Fisher]

Hi Belinda Njiro ,

Currently metan is not designed to accept more than one subgrouping variable within the by() option. This is what is meant by the error "name: too many specified", although I admit that it is unclear.

If you wish to use metan to accomplish this task, one way to do it is to run the two subgroup analyses separately, then combine the results-sets prior to creating the forest plot.
Not having access to your data, I will demonstrate this using the dataset used in the documentation for meta summarize:

use https://www.stata-press.com/data/r18/pupiliqset, clear
keep in 1/10    

* Using meta:
meta forestplot, subgroup(week1 tester)

* Using metan:
* 1. Run the two subgroup analyses separately and save the results-sets
metan stdmdiff se, study(studylbl) effect(SMD) model(reml) nomodellabels by(week1) nogr summaryonly saving(week1, stacklabel replace)
metan stdmdiff se, study(studylbl) effect(SMD) model(reml) nomodellabels by(tester) nogr summaryonly saving(tester, stacklabel replace)

* 2. Load and append the results-sets
preserve
use week1, clear
append using tester, gen(append)

* 3. Housekeeping (hard to explain in general terms)
gen sortby = _n
expand 2 if _USE==4 & append, gen(expand)
drop if _USE==6
replace _USE = 6 if _USE==5 & !append
replace _USE = 6 if _USE==4 &  expand
replace _pvalue = . if _USE==6
sort sortby expand

replace _USE=1 if _USE==3
label variable _LABELS "Subgroup"
label variable _pvalue "p-value"

* 4. Create the forest plot.
forestplot, useopts rcols(_pvalue) nowt xlabel(-.5(.5)1, format(%3.1g)) astext(60) name(metanf,replace)
restore

As the maintainer of the metan package, I will consider adding multiple-subgroup functionality to a subsequent version.

Best wishes,

David.