Twoway Histogram

[Joshua Smith]

Dear All,
I would like to create a two-way histogram for two variables. However, I would like a variable to be in a panel and the other variables being below it. Is it possible? In other words, I would like to obtain the attached graph using two-

way histogram. The code I use is

twoway (histogram pscore if distance>=0, color(green%30)) (histogram pscore if distance<0, color(red%30))

which of course overlaps the two distributions.

Thank you very much for considering my request!

[Nick Cox]

Here are some small tricks

sysuse auto, clear

twoway__histogram_gen mpg if foreign, start(10) width(2) freq gen(f1 v1)
twoway__histogram_gen mpg if !foreign, start(10) width(2) freq gen(f2 v2)

replace f1 = -f1 

twoway bar f1 v1, barw(2) fcolor(stc2*0.2) lcolor(stc2) ///
|| bar f2 v2, barw(2) fcolor(stc1*0.2) lcolor(stc1) legend(order(2 "Domestic" 1 "Foreign")) /// 
xtitle("`: var label mpg'") yla(-5 "5" 0(5)15)

[Joshua Smith]

This works perfectly, thank you so much!

[Nick Cox]

Consider also superimposed histograms:

sysuse auto, clear

twoway histogram mpg if foreign, start(10) width(2) freq lcolor(stc2) fcolor(stc2%20) ///
|| histogram mpg if !foreign, start(10) width(2) freq lcolor(stc1) fcolor(stc1%20) ///
legend(order(2 "Domestic" 1 "Foreign")) xtitle("`: var label mpg'")  

twoway histogram mpg if foreign, start(10) width(2) lcolor(stc2) fcolor(stc2%20) ///
|| histogram mpg if !foreign, start(10) width(2) lcolor(stc1) fcolor(stc1%20) ///
legend(order(2 "Domestic" 1 "Foreign")) xtitle("`: var label mpg'")

and indeed quantile plots e.g. https://www.statalist.org/forums/for...lable-from-ssc

[John Mullahy]

The use of

twoway__histogram_gen

in #2 is more evidence why most or all undocumented commands should not be undocumented. See

help undocumented

[Nick Cox]

A serious detail about #1 is that red and green together are a big challenge for many people. See e.g. https://www.nei.nih.gov/learn-about-...olor-blindness