coefplot line color

[Sa Fe]

Hi
I was wondering how I can change the color of a graph line generated by coefplot. here is my code:

coefplot , drop(_cons) vertical baselevels ///
ci(95) ciopts(recast(rcap) alcolor(%60)) recast(connected) ///
ylabel(#9, grid) ytitle("Percentage, %") ///

And I get the attached graph. the color of the line is blue. I want to change it to other colors. I'd appreciate your insights on that.

Thanks,

[Andrew Musau]

coefplot is from SSC, as you are asked to explain (FAQ Advice #12).

lcolor(whatever)

?

[Sa Fe]

coefplot is from SSC, as you are asked to explain (FAQ Advice #12).

lcolor(whatever)

?

when I add the lcolor(black) command I get this graph:

[Stephen Jenkins]

help coefplot##plotopts suggests that lcolor (and lpattern) are not options to -coefplot- (from SSC, by Ben Jann Ben Jann) . My experiments to date, based on the auto data set, and the -coefplot- webpages as well as the original SJ article, suggest this as well. I'd be pleased to be shown I am wrong!

[Andrew Musau]

help coefplot##plotopts suggests that lcolor (and lpattern) are not options to -coefplot- ... I'd be pleased to be shown I am wrong!

With -recast()-, you are calling a twoway plot type. As such, twoway options such as -lcolor()- and -lpattern()- are allowed. An example:

sysuse auto
regress mpg i.rep78
set scheme s1mono
coefplot, recast(connected) lp(dash) lc(blue) drop(_cons)

[Sa Fe]

With -recast()-, you are calling a twoway plot type. As such, twoway options such as -lcolor()- and -lpattern()- are allowed. An example:

sysuse auto
regress mpg i.rep78
set scheme s1mono
coefplot, recast(connected) lp(dash) lc(blue) drop(_cons)

[ATTACH=CONFIG]n1714405[/ATTACH]

Got you. Thanks for clarigying that. But still with that being notified, I'm not able to change the color of lines in the coefplot when I'm trying to plot multiple models. take this example:

 
 coefplot model_1 model_2 model_3 , drop(_cons) vertical baselevels /// ci(95) ciopts(recast(rcap) alcolor(%60)) recast(connected) /// ylabel(#9, grid) ytitle("Percentage, %")

in this code, how can I change the color for each line separately?

[Sa Fe]

just as an extra request, want to label each line on the line not in the legend in the coefplot. something like this

Is there a way to do this?

[Andrew Musau]

You are just showing code. Provide a reproducible example (see FAQ Advice #12 for details on how to do this).

[Sa Fe]

You are just showing code. Provide a reproducible example (see FAQ Advice #12 for details on how to do this).

sysuse bpwide, clear
estimates clear
regress bp_after i.agegrp if sex==0
estimates store model_1
regress bp_after i.agegrp if sex==1
estimates store model_2
coefplot model_1 model_2, recast(connected) drop(_cons)

this will generate the following graph. i want to set other colors for each line (preferably via the hex code).

[Stephen Jenkins]

thanks, Andrew. Apologies if I wasn't clear. What I meant to say is that I cannot change the colour or pattern of each CI 'bar'. Look at the following:

sysuse auto, clear
 
regress price mpg trunk length turn if foreign==0
estimates store A
regress price mpg trunk length turn if foreign==1
estimates store B
coefplot (A, label(Domestic Cars) pstyle(p3) msym(oh) ) ///
     (B, label(Foreign Cars) pstyle(p4)  msym(sh))   ///
     , drop(_cons) xline(0)

So, I can change the marker symbols that represent each of the estimates. However the other details of the point and CI bar appear to be controllable only using pstyle calls (as in Ben's documentation). What I can't see how to do is change the colours (or bar's line pattern) in any other way

[Andrew Musau]

What I can't see how to do is change the colours (or bar's line pattern) in any other way

You do this within -ciopts()-

sysuse auto, clear
 
regress price mpg trunk length turn if foreign==0
estimates store A
regress price mpg trunk length turn if foreign==1
estimates store B
coefplot (A, label(Domestic Cars) pstyle(p3) ciopts(bcolor(blue)) msym(oh) ) ///
     (B, label(Foreign Cars) pstyle(p4)  ciopts(bcolor(red)) msym(sh))   ///
     , drop(_cons) xline(0)

[Andrew Musau]

this will generate the following graph. i want to set other colors for each line (preferably via the hex code).

sysuse bpwide, clear
estimates clear
regress bp_after i.agegrp if sex==0
estimates store model_1
regress bp_after i.agegrp if sex==1
estimates store model_2
set scheme s1mono
coefplot (model_1, recast(connected) lc(red)) (model_2, recast(connected) lc(blue)), drop(_cons)

[Stephen Jenkins]

Andrew: you're a champ! Many thanks. (Obvious now -- in hindsight) I can confirm that lpattern works inside ciopts() too

[Sa Fe]

[QUOTE=Andrew Musau;n1714452]

thank you very much. It worked.