Missing values

[sandeep kaur]

Hi,

I am replacing all values for score >=9.5 as 1 and less than 9.5 as 0, but stata is picking up even missing values desiganated as "." in dataser under score>=9.5. How do it avoid it and why missing values are included under it?

gen adfibsc=.
replace adfibsc=1 if Fscore >=9.5
replace adfibsc=0 if Fscore <9.5
label define adfibsc 0"nofib" 1"fib"
label values adfibsc adfibsc
codebook adfibsc

[Daniel Schaefer]

In Stata, missing values are treated as the largest possible number. This is so that comparisons with missing values can resolve into either true or false. Different languages treat missing values differently, but you should always try to explicitly account for missingness in any language.

replace adfibsc=1 if Fscore >=9.5 & !missing(Fscore)

[Joro Kolev]

Stata also understands logical expressions, so what you want to do can be easier done by

gen adfibsc = Fscore >=9.5 if !missing(Fscore)

[Carlo Lazzaro]

Sandeep:
another approach might be:

. set obs 10
Number of observations (_N) was 0, now 10.

. g adfibsc=.

. g Fscore=runiform()*15

. replace adfibsc=cond(Fscore>9.5,1,0) if !missing(Fscore)

. list

     +--------------------+
     | adfibsc     Fscore |
     |--------------------|
  1. |       1   13.97902 |
  2. |       0   6.823323 |
  3. |       0   1.011016 |
  4. |       0   5.069833 |
  5. |       1   14.62327 |
     |--------------------|
  6. |       1   10.89658 |
  7. |       0   .6812268 |
  8. |       1    11.1895 |
  9. |       0   7.441888 |
 10. |       1   10.75074 |
     +--------------------+

.

[sandeep kaur]

Thanks everyone for response.