coding row_column

[ajay pasi]

Hi statalist community, may someone offer some help?

* Example generated by -dataex-. For more info, type help dataex
clear
input byte(house_id person_id) str6 person_sex byte spouse_id str6 spouse_sex byte person_score
1  1 "male "  2 "female" 4
1  2 "female" 1 "male "  6
1  3 "male "  . ""       6
1  4 "male "  . ""       3
1  5 "female" . ""       9
1  6 "male "  8 "female" 2
1  7 "female" . ""       0
1  8 "female" 6 "male "  1
1  9 "male "  . ""       6
1 10 "male "  . ""       8
2  1 "female" 4 "male "  4
2  2 "male "  . ""       6
2  3 "male "  . ""       6
2  4 "male "  1 "female" 3
2  5 "female" . ""       9
2  6 "female" 8 "male "  2
2  7 "female" . ""       0
2  8 "male "  6 "female" 1
end

This dataset does not have spouse_score, which is needed for the analysis in my research. May someone please help in deriving spouse_score?

regards
ajay

[Nick Cox]

"coding row_column" is a fairly unhelpful title, especially as you have used similar cryptic titles in the past.

Something specific like "generating spouse score from data on couples" would have been much better as a title.

See https://www.statalist.org/forums/help#topiclines for advice and note that many people will use a title as criterion for whether to read further. A title that doesn't look interesting cuts down your readership immediately.

The problem yields to rangestat from SSC after one minor twist.

* Example generated by -dataex-. For more info, type help dataex
clear
input byte(house_id person_id) str6 person_sex byte spouse_id str6 spouse_sex byte person_score
1  1 "male "  2 "female" 4
1  2 "female" 1 "male "  6
1  3 "male "  . ""       6
1  4 "male "  . ""       3
1  5 "female" . ""       9
1  6 "male "  8 "female" 2
1  7 "female" . ""       0
1  8 "female" 6 "male "  1
1  9 "male "  . ""       6
1 10 "male "  . ""       8
2  1 "female" 4 "male "  4
2  2 "male "  . ""       6
2  3 "male "  . ""       6
2  4 "male "  1 "female" 3
2  5 "female" . ""       9
2  6 "female" 8 "male "  2
2  7 "female" . ""       0
2  8 "male "  6 "female" 1
end

gen use_as_id = cond(spouse_id < ., spouse_id, 0) 
rangestat spouse_score=person_score, int(person_id use_as_id use_as_id) by(house_id) 

ds use_as_id, not 

list `r(varlist)', sepby(house_id)

     +----------------------------------------------------------------------------+
     | house_id   person~d   person~x   spouse~d   spouse~x   person~e   spouse~e |
     |----------------------------------------------------------------------------|
  1. |        1          1      male           2     female          4          6 |
  2. |        1          2     female          1      male           6          4 |
  3. |        1          3      male           .                     6          . |
  4. |        1          4      male           .                     3          . |
  5. |        1          5     female          .                     9          . |
  6. |        1          6      male           8     female          2          1 |
  7. |        1          7     female          .                     0          . |
  8. |        1          8     female          6      male           1          2 |
  9. |        1          9      male           .                     6          . |
 10. |        1         10      male           .                     8          . |
     |----------------------------------------------------------------------------|
 11. |        2          1     female          4      male           4          3 |
 12. |        2          2      male           .                     6          . |
 13. |        2          3      male           .                     6          . |
 14. |        2          4      male           1     female          3          4 |
 15. |        2          5     female          .                     9          . |
 16. |        2          6     female          8      male           2          1 |
 17. |        2          7     female          .                     0          . |
 18. |        2          8      male           6     female          1          2 |
     +----------------------------------------------------------------------------+

.

[ajay pasi]

thank you sir, I would mind your suggestion about the title, in future posts.