Renaming each variable label as a substring of old label

[Weston Ley]

I have a set of variables v1 through v154 that I want to relabel by excluding the first 16 characters of the original label. The following code expresses what I want to do, but it is not in proper syntax since you cannot use the substr() function in the label variable command.
foreach x of varlist v1-v154 {
local varlabel : var label `x'
label variable `x' substr("`varlabel'",17,.)
}
How do I achieve my task?

[Hemanshu Kumar]

foreach x of varlist v1-v154 {
    local varlabel : var label `x'
    label variable `x' "`=substr("`varlabel'",17,.)'"
}

[Weston Ley]

Thank you Hemanshu. Can you provide intuition for why there needs to be an equal sign in front of substr()?

[Hemanshu Kumar]

The syntax is

 label variable varname ["label"]

So Stata is going to read the part after the variable name as the literal string substr("`varlabel'",17,.) (after substituting in the content of the varlabel macro, of course). This is not what you want; you want the substr() function to be evaluated. That necessitates the `=...'

[Clyde Schechter]

Re #3. The -label var- command expects a literal string as its final argument. By itself substr(whatever) is not a literal string: it is an expression using a Stata function that if evaluated will be a literal string. The `=any_expression' syntax is Stata macro-speak for: evaluate the expression and replace this by the result of that evaluation.

Added: Crossed with #4.

[Ali Atia]

More broadly, the `=<exp>' syntax indicates that you would like whatever expression is in between those delimiters to be evaluated in-line and have the result substituted. So:

 label variable `x' "`=substr("`varlabel'",17,.)'"

Is functionally equivalent to:

local expression = substr("`varlabel'",17,.)
label variable `x' "`expression'"

The only difference is that in the former instance, the expression is evaluated in-line and in the latter instance the expression is first assigned to a local macro.

For more information, see: pmacro.pdf (stata.com), specifically page 14 on "Macro expansion operators and function."

Edit: Crossed with #5