Loop mixed model over a least of predictors and store the coefficients and P values

[Sergio Serrano]

Hi,

I want to loop a mixed model over a list of predictors (fixed effects) and store the coefficients and P values in Stata v. 17.

sysuse auto, clear

xtmixed price mpg || foreign:, covariance(independent) vce(robust)

foreach var of varlist mpg-gear_ratio {
    xtmixed price `var' || foreign:, covariance(exchangeable) vce(robust)
}

Can anyone help me with how to proceed to store the coefficients and P values of the fixed effect for each model?

Thanks in advance,

Sergio

[Ken Chui]

sysuse auto, clear

xtmixed price mpg || foreign:, covariance(independent) vce(robust)

foreach var of varlist mpg-gear_ratio {
    xtmixed price `var' || foreign:, covariance(exchangeable) vce(robust)
    matrix m_`var' = r(table)
}

foreach var of varlist mpg-gear_ratio {
    mat list m_`var'
}

[Sergio Serrano]

Thank you for the fast and useful reply!
To make the process fully automatic, I would still need to extract the Coefficient and P value of each variable of "varlist" to create a table like the one below.

Variable	Coef	P
rep78	0.7	0.12
headroom	1.3	0.33
trunk	2.2	0.44
...	...	...

Any help will be appreciated.

[Ken Chui]

sysuse auto, clear

foreach var of varlist mpg-gear_ratio {
    xtmixed price `var' || foreign:, covariance(exchangeable) vce(robust)
    matrix m_`var' = r(table)
}

generate xvar = ""
generate beta = .
generate pval = .

local counter = 1
foreach var of varlist mpg-gear_ratio {
    replace xvar = "`var'" in `counter'
    replace beta = m_`var'[1,1] in `counter'
    replace pval = m_`var'[4,1] in `counter'
    local counter = `counter' + 1
}

browse xvar beta pval in 1/9

[Sergio Serrano]

You nailed it. Thank you so much!

[Ken Chui]

You nailed it. Thank you so much!

You are welcome. It can probably be slimmed down to just one loop since it seems saving the matrix is no longer the focus:

sysuse auto, clear

generate xvar = ""
generate beta = .
generate pval = .
local counter = 1

foreach var of varlist mpg-gear_ratio {
    xtmixed price `var' || foreign:, covariance(exchangeable) vce(robust)
    replace xvar = "`var'" in `counter'
    replace beta = r(table)[1,1] in `counter'
    replace pval = r(table)[4,1] in `counter'
    local counter = `counter' + 1
}

browse xvar beta pval in 1/9