Plotting the results from the margins command

[Klaus Steitzel]

Hi everyone

I have an analysis kind of like this:

webuse nlswork, clear
xtset idcode

xtreg ln_w ttl_exp, re
qui margins, at(ttl_exp=(0(5)30))
qui marginsplot, recastci(rarea) recast(line) title(Random effects w/out controls) name(one, replace)

xtreg ln_w ttl_exp grade age c.age#c.age 2.race not_smsa south, re
qui margins, at(ttl_exp=(0(5)30))
qui marginsplot, recastci(rarea) recast(line) title(Random effects w/ controls) name(two, replace)

xtreg ln_w ttl_exp, fe
qui margins, at(ttl_exp=(0(5)30))
qui marginsplot, recastci(rarea) recast(line) title(Fixed effects w/out controls) name(three, replace)

xtreg ln_w ttl_exp grade age c.age#c.age 2.race not_smsa south, fe
qui margins, at(ttl_exp=(0(5)30))
qui marginsplot, recastci(rarea) recast(line) title(Fixed effects w/controls) name(four, replace)

I.e. I have a set of models that differ in one way or another and I am using margins to illustrate the slope of treatment across models.

I can plot those slopes like this:

graph combine one two three four, col(2) ycommon

and this looks like this:

But I don't like the small-multiples aspect of the figure. Is there a simple way I can plot the lines and the confidence intervals overlaid in the same figure?

In case this verbal description of my desired figure wasn't clear I am also providing a simulation I did in MS Paint:

Thanks for your consideration
KS

[Andrew Musau]

ssc install combomarginsplot
help combomarginsplot

This may help: https://www.statalist.org/forums/for...ne-marginsplot

[Klaus Steitzel]

Amazing, thank you!

webuse nlswork, clear
xtset idcode

tempfile one two three four

xtreg ln_w ttl_exp, re
qui margins, at(ttl_exp=(0(5)30)) saving(`one', replace)

xtreg ln_w ttl_exp grade age c.age#c.age 2.race not_smsa south, re
qui margins, at(ttl_exp=(0(5)30)) saving(`two', replace)

xtreg ln_w ttl_exp, fe
qui margins, at(ttl_exp=(0(5)30)) saving(`three', replace)

xtreg ln_w ttl_exp grade age c.age#c.age 2.race not_smsa south, fe
qui margins, at(ttl_exp=(0(5)30)) saving(`four', replace)

combomarginsplot `one' `two' `three' `four', labels("RE" "RE w/ controls" "FE" "FE w/ controls")