Conducting firm fixed effect analysis with subsample

[Klaus Klausen]

Hi,

I am trying to replicate the results of a study that examines the effect of manager board connections on corporate takeovers. Specifically, the paper answers the question whether the fact that executives of the acquiring firm A and the target firm B share a common board seat in another company C. The authors rely on a cross sectional dataset.
In the robustness test section, the authors conduct an analysis with firm fixed effects.

Specifically the authors write:

To further control for any other unobservable or omitted acquirer characteristics which could affect both board connections and M&A outcomes, we conduct an analysis with firm fixed effects. This specification will not rule out all remaining omitted variables problems, but it will help control for time-invariant acquirer characteristics. Specifically, we compare the deals in which the acquirer has a board connection to the target with those deals by the same acquirer in which the acquirer has no board connection to the target. Put differently, keeping the identity of the acquirer fixed, we compare the connected and non-connected deals made by the same acquirer. Our sample size reduces significantly to 318 in this specification since we focus only on the deals made by those acquirers which undertake at least one acquisition where they have a board connection to the target.

I do understand the underlying idea but struggle to replicate it. Essentially, what the authors did is that they
only keep acquirer in their sample that i) conducted more than one deal and ii) in which in one deal there was a board connection and in another there was no board connection. This way, they keep the acquiring firm constant so that they are able to control for time-invariant effects on the acquirer-level.

Consider the following data example whereas each entry is one deal. Acq_ID refers to the ID of an acquiring firm and Connection is a dummy that equals 1 if -in a given deal - there is board connection and 0 otherwise. Deal_CAR are the cumulative abnormal returns, i.e., the performance indicator of a given deal.

* Example generated by -dataex-. For more info, type help dataex
clear
input long Acq_ID float Connection double Deal_CAR
 71 0   .9519993984731437
 71 0   .8364199986664539
 71 0  -1.541903500906821
 73 1  .19511691836717038
 73 1  -4.787644069315418
 73 0  2.6460057110489537
112 0 -2.2986211045901275
112 0   .5411933399895202
113 0  2.4946974085581974
113 0  -.5403433136260304
113 0  .48504035524075445
113 0  -4.487339976030167
124 0  3.6687205514550456
151 0   3.590825426789135
151 0   .7502576503749855
151 0   .5536335988657116
151 0 .026392322621639295
152 0   12.47101824461725
152 0  3.9530808072579684
152 0    9.36308608910677
190 0   -5.22601741072109
190 0 -3.6346442715639484
190 1  -2.644106849677599
190 0  -1.762056906238326
275 0 -13.816844600049105
276 0   -1.07461278651107
276 0  4.0346841181037885
276 0   3.582171326103593
324 0   1.850095552909985
324 0  -5.913551001671871
324 0  .31846880674315653
324 0  -7.896034254994485
324 0  1.3271396580365893
324 0  -6.398814218036208
324 0   2.983633572428436
324 0   5.072822046456308
335 1   5.890566950790053
335 0 -10.516050924879018
end

My code so far:

bysort Acq_ID: egen Acq_Deals = count(Acq_ID)
drop if Acq_Deals < 2 //Only keep companies that conducted more than 1 acquisition
drop Acq_Deals

bysort Acq_ID: egen summ = sum(Connection) //Acquiring firms whose deals differ with respect to the connection take on a value >= 1
drop if summ == 0 //Drop Deals where the connection variable does not vary
drop summ

As to my understanding, the authors compare the means of the cumulative abnormal returns of a given deal where the acquirer has board connections with the target to the CAR of deals where the same acquirer has no connections to the target. My approach:

ttest Deal_CAR, by(Connection)

However, using this command, I would compare the mean CAR over all connected deals with the mean CAR of all non-connected deals, right? So there isn't a comparison on the same acquirer level as stated by the author.
I would really appreciate if someone could tell me if my approach is correct so far and what the next step would be.

[Clyde Schechter]

I think what you want is:

xtset Acq_ID
xtreg Deal_CAR i.Connection, fe

As an aside, a couple of suggestions about the code that trims the data set to the desired subset. (These are optional improvements: the code you wrote produces the correct results. It just could be written better.) The -egen- function -sum()- was long ago renamed to -total()-. While Stata will still accept -sum()- with -egen-, it is best to avoid it because it is easy to confuse with the function -sum()- used by -generate- and -replace- which calculates a running sum instead of a grand total. Also, the code that drops Acq_IDs that do not meet the requirements can be greatly simplified to just one line:

by Acq_ID (Connection), sort: keep if _N > 1 & Connection[_N] == 1

[Klaus Klausen]

Dear Clyde,
thank you very much for your answer. I really appreciate the tips for improving my code.
The authors also run the fixed effect regression suggested by you. However, I think they also performed a simple comparison of the means (see attached picture). Any suggestions?

[Clyde Schechter]

I'm not sure I understand their Table 5. It may be that columns (2) and (4) were obtained from running -margins Connection- after the -xtreg, fe- command. But that's really just a guess. They don't really explain their methods clearly in what you show.

[Klaus Klausen]

They don't really explain their approach any further expect for what I have posted unfortunately. I thought they might have applied a simple t test but am not really sure about that.
Thank you

[Clyde Schechter]

Well, if they did apply a simple t-test, you should disregard their results, because that is not a valid approach to data with this structure.

[Klaus Klausen]

Hi Clyde,
I am trying to estimate a fixed effect model as suggested by you.
The authors state that this method results in a substantial loss of observations, as they only focus only on the deals made by those acquirers which undertake at least one acquisition where they have a board connection to the target.
Most of the other paper I have read on this topic (and that had cross-sectional data) note that if they conduct firm fixed effects analysis, it will result in a loss of observations as they focus on those firms in their sample that made more than 1 acquisition.

So I would run the commands posted in #1 and only keep acquiring firms that did more than 1 acquisition and whose deals differ with respect to the connection take on a value >= 1

Then:

set Acq_ID
xtreg Deal_CAR i.Connection i.Deal_Year_Announced, fe vce(robust) //Include Firm and Year Fixed effects by including the Announcement Year of a deal

Do you think this would be an appropriate approach to control for time-invariant firm characteristics in a cross-sectional dataset?
I am not really sure how that would compare those acquirers to each other that conducted several acquisitions with varying i.connection.
Thanks

[Clyde Schechter]

One quick correction to your code: it's -xtset-, not -set-. Stata has a -set- command but it is unrelated to what you want to do, and -sets Acq_ID- would be a syntax error with it.

After you fix that, yes this would adjust (not control--there is no such thing as control in observational data, common abuse of language notwithstanding) for all time-invariant acquiring firm characteristics.

I am not really sure how that would compare those acquirers to each other that conducted several acquisitions with varying i.connection.

It doesn't. It is purely a within-acquiring firm comparison of those deals where there is a connection to those deals where there isn't. You cannot do a cross-acquiring firms comparison using a fixed-effects model.

That said, although I do not work in finance and know very little about it, my intuition is that an inquiry into the effect of connection on the outcomes of acquisitions within firms seems salient. What is your specific research goal? Does it call for a within- or across-firms contrast?

[Klaus Klausen]

Thanks Clyde, this is really helpful.

I wasn’t very clear on the last point. What I meant is:

I am not really sure how that would compare those acquirers to each other (in terms of compare to itself, so acquirer A to acquirer A, B to B etc.) that conducted several acquisitions with varying i.connection.

Sorry for the confusion.

So at first, I didn’t really get the idea how to compare the same acquirer to each other, just with varying management connection (as stated in the paper). After reading some really good papers on this topic things became clearer though.
I am desired to observe the within firm variation and eliminate the between variation. This is to make sure it isn’t the time invariant differences between firms (e.g., different industry) that explains merger performance.

[Clyde Schechter]

I am desired to observe the within firm variation and eliminate the between variation. This is to make sure it isn’t the time invariant differences between firms (e.g., different industry) that explains merger performance.

Then a fixed-effects model is precisely what you need.