Macros that can be read by programs

[Colette Salemi]

I developed a program to perform regressions and numerous post-estimation commands. I'm running many regressions, so writing a program is much more efficient than copy-pasting each time. To demonstrate, consider this basic program with Stata's car dataset:

sysuse auto.dta, clear

program myProgram

reg price `1' if `2'
est store res_`1'

end

This allows me to run the program, each time specifying the independent variable and the if condition:

myProgram mpg `"make!="Ford Mustang" & make!="Honda Accord""'
myProgram trunk `"make!="Ford Mustang" & make!="Honda Accord""'
myProgram length `"make!="Ford Mustang" & make!="Honda Accord""'
myProgram weight `"make!="Ford Mustang" & make!="Honda Accord""'

When the if condition does not change, like in the case above, I would like to define an object that stores the condition so that I just have to refer to that object (and not the entire condition). I have tried doing this with a global macro:

global ifCondition `"make!="Ford Mustang" & make!="Honda Accord""'

But when I then try to execute the program using the if condition:

myProgram mpg $ifCondition

Stata returns the error:

Invalid syntax

Do I have to redefine the global macro, and if yes, how? Alternatively, is there some other macro I could use?

Also, please note that putting the if condition into the program is not an answer. I need the program to be flexible to different if conditions.

[Daniel Schaefer]

Hi Colette,

One of the awesome things about Stata macros is that they can store lines of executable code as well as things like strings! The following line works on my end:

global ifCondition = make!="Ford Mustang" & make!="Honda Accord"

[Nick Cox]

#2 The global will be evaluated using values in observation 1. That is unlikely to be what anyone wants. Adding the equals sign is not the solution.


But I can’t yet see what is wrong with #1.

[Colette Salemi]

Hi Colette,

One of the awesome things about Stata macros is that they can store lines of executable code as well as things like strings! The following line works on my end:

global ifCondition = make!="Ford Mustang" & make!="Honda Accord"

Thank you for trying to help. When I tried this code, the program executed, but it did not apply the if condition (N=74, the number of obs. instead of N=72, the number of obs, minus those two car makes).

[Sven-Kristjan Bormann]

Just run

 myProgram mpg `"$ifCondition"'

Stata removes the quotation marks at the beginning and the end of the string when you put it into a macro.

[Colette Salemi]

Just run

 myProgram mpg `"$ifCondition"'

Stata removes the quotation marks at the beginning and the end of the string when you put it into a macro.

Thank you! This worked!!

[Daniel Schaefer]

Nick Cox I definitely wasn't thinking the equals sign was the solution. Much worse I'm afraid. I striped the quotes from the line, and imagined that the interpreter knew how to store the expression and evaluate it in the right context. That is, of course, completely wrong. Obviously if the line isn't wrapped in quotes, the line is executed then and there. What was I thinking?

[Nick Cox]

I think I missed the obvious too. This will work too.

 
 global ifCondition `" `"make!="Ford Mustang" & make!="Honda Accord""' "'

as each time the global is processed the outermost quotation marks are stripped.

[Bjarte Aagnes]

set trace on
set traceexpand on

will help debug code.

One alternative can be to prevent/delay macro expansion using "\".

global IF make!="Ford Mustang" & make!="Honda Accord"

qui myProgram mpg \$IF

. di `"`e(cmdline)'"
regress price mpg if make!="Ford Mustang" & make!="Honda Accord""

And, the syntax command is an alternative to parse args:

program myRegPriceProgram

syntax varlist(max=1) if

local x1 `varlist'
  
reg price `x1' `if'

est store res_`x1'

end

sysuse auto

global IF make!="Ford Mustang" & make!="Honda Accord"

myRegPriceProgram mpg if $IF