How to modify individual graph's title on combined graph

[Chen Samulsion]

Dear Stata users,
Suppose we have a combined graph that is composed of two individual graphs, let's say them left panel and right panel. Now I want to modify titles of the two panels. How can I achieve? Thank you.

sysuse auto
twoway connected price mpg, sort name(graph1) title(Title of Graph 1)
twoway connected weight mpg, sort name(graph2) title(Title of Graph 2)
graph combine graph1 graph2, name(graph3)

[Andrew Musau]

You can use the undocumented gr_edit command.

sysuse auto, clear
twoway connected price mpg, sort name(graph1, replace) title(Title of Graph 1)
twoway connected weight mpg, sort name(graph2, replace) title(Title of Graph 2)
graph combine graph1 graph2, name(graph3, replace)

local titles `" "My title 1" "My title 2"'
forval i=1/2{
    gr_edit .plotregion1.graph`i'.title.text = {}
    gr_edit .plotregion1.graph`i'.title.text.Arrpush "`:word `i' of `titles''"
}

[Chen Samulsion]

Thank you so much Andrew Musau.
It seems that this is a complicated question without any easy solution by which I mean ready-made commands.