String to numeric value

[Morten Hans Jensen]

I have a string variable that contains a number of days: "3 days", "76 days" and so on.
I want to extract the number part of this and put it into a new numeric variable.

I have started with removing the space:

replace duration = subinstr(duration, " ", "", .)

so it now reads: "3days", "76days"

I have then tried to extract it with forvalues but cannot get it to work. Any suggestions?

[Rich Goldstein]

if "days" are the only characters you need to worry about, then use -destring- with the ignore option; here is an example but, since you did not supply a data example, I can't be sure it will cover all your issues:

destring duration, gen(duration2) ignore("days")

please see

h destring

[Nick Cox]

For your data example the solution you tried makes things worse. Try

gen wanted = real(word(duration, 1))

or

destring duration, ignore(“days”) gen(wanted)

[Igor Paploski]

Hi Morten,

You can try:

egen duration2 = sieve(duration), keep(numeric)

This will remove any non-numeric characters from duration. But be aware, if you have an observation that is "3 days, 5 hours", the end result would be "35".

[daniel klein]

I would probably do something like

generate duration_numeric = real(subinstr(duration, "days", "", 1))

which will create missing values for observations with a pattern other than "# days".

edit:

even more restrictive:

generate duration_numeric = real(regexs(1)) if regexm(duration, "^([0-9]+) days$")

[Nick Cox]

#4 requires that you have installed a community-contributed package, namely

ssc install egenmore

[Morten Hans Jensen]

Thank you all for your suggestions!

They do however not solve my problem because I have been too unclear - sorry for the waste of your time.

There are other possibilities in the string such as: "day", "days", "week", "weeks", "month", "months", "don't know" and so on.
I have not been able to figure this out myself.

[Andrew Musau]

Extracting digits is not too difficult, but if there are irrelevant details, then you need to spell out some criteria on what is relevant. Assuming that the description immediately follows the digits, you can write out a regular expression along the following lines:

clear
input str29 duration
"12 days"
"20000 steps in 100 MONTHS"
"20 kilometers"
"don't know"
"22 Weeks"
"33Months"
end

gen which=regexs(0)+"s" if regexm(lower(duration), "(day|week|month)")
gen wanted= real(ustrregexs(1)) if ustrregexm(lower(duration),"(\d+)(\s*)(day|week|month)"), before(which)

Res.:

. l, sep(0)

     +---------------------------------------------+
     |                  duration   wanted    which |
     |---------------------------------------------|
  1. |                   12 days       12     days |
  2. | 20000 steps in 100 MONTHS      100   months |
  3. |             20 kilometers        .          |
  4. |                don't know        .          |
  5. |                  22 Weeks       22    weeks |
  6. |                  33Months       33   months |
     +---------------------------------------------+

[Rich Goldstein]

alternatively, you can add more characters to the "ignore" option and you can find them, or the ones remaining after a first trial, via something like:

ta duration if real(duration)==.

note that #2 above explained about the problems for us caused by you not supplying a data example