Help me clean my variables please.

[Namo Salih]

I have downloaded an xlsx spreadsheet with some data. The data is formated with a numeric value and a subsequent text like this: 4. Agree.
When I transfer all the data to stata I dont get all the values 1 - 5; i get only the ones that have been answered; 1,3,5.

How can I edit my variables so that all of the ones that this applies to gets the same values example:

1. Very disagree = 3
2. Disagree = 0
3. Neither agree or disagree = 5
4. Agree = 0
5. Very much agree =17
.b Dont know = 2

I hope I make myself clear.

[Jared Greathouse]

No you don't make yourself clear. Please use the dataex command to present how your real data look like in Stata. Also, where did you download this dataset from? If it's public and easily accessible, please give the link to it.

[Namo Salih]

I gathered the data on my own and am unfortinatly not at liberty do share.

. fre opp1

opp1 -- Jeg oppmuntrer til bruk av standardiserte prosedyrer.
----------------------------------------------------------------------------------
| Freq. Percent Valid Cum.
-------------------------------------+--------------------------------------------
2. Uenig | 3 7.14 7.14 7.14
3. Verken enig eller uenig | 11 26.19 26.19 33.33
4. Enig | 21 50.00 50.00 83.33
5. Veldig enig | 7 16.67 16.67 100.00
Total | 42 100.00 100.00
----------------------------------------------------------------------------------
My problem is that the dataset that i downloaded from my web questionaire has the different categories defined as 1. Veldi uenig (very disagree) - 5. Veldig enig.

As you can see from "opp1" i am unable to see the category 1. ; that no one responded to.

I wish to see all the categories because this varies from all the questions which categories are missing and this messes with my data.

I need opp1, opp2, opp3, opp4 etc to all include category 1 - 5 even if two or three categories are missing.

I apologize if I am unclear; this is my first time working with stata and I'm doing it on my own so kind of difficult to wrap my head around.

[William Lisowski]

You are apparently using the community-contributed fre command available from SSC.

Consider the following, where I have invented data that matches your description of your data.

* Example generated by -dataex-. For more info, type help dataex
clear
input str26 opp1
"2. Uenig"                  
"3. Verken enig eller uenig"
"3. Verken enig eller uenig"
"2. Uenig"                  
"3. Verken enig eller uenig"
"4. Enig"                   
"3. Verken enig eller uenig"
"3. Verken enig eller uenig"
"5. Veldig enig"            
"5. Veldig enig"            
"3. Verken enig eller uenig"
"3. Verken enig eller uenig"
"4. Enig"                   
"2. Uenig"                  
"2. Uenig"                  
"5. Veldig enig"            
"4. Enig"                   
"4. Enig"                   
"4. Enig"                   
"3. Verken enig eller uenig"
end
replace opp1 = substr(opp1,4,.)
label define VAL 1 "Veldi uenig" ///
                 2 "Uenig" ///
                 3 "Verken enig eller uenig" ///
                 4 "Enig" ///
                 5 "Veldig enig"
encode opp1, generate(opp1n) label(VAL)
list in 1/5, clean 
list in 1/5, clean nolabel
fre opp1n
fre opp1n, includelabeled

. list in 1/5, clean 

                          opp1                     opp1n  
  1.                     Uenig                     Uenig  
  2.   Verken enig eller uenig   Verken enig eller uenig  
  3.   Verken enig eller uenig   Verken enig eller uenig  
  4.                     Uenig                     Uenig  
  5.   Verken enig eller uenig   Verken enig eller uenig  

. list in 1/5, clean nolabel

                          opp1   opp1n  
  1.                     Uenig       2  
  2.   Verken enig eller uenig       3  
  3.   Verken enig eller uenig       3  
  4.                     Uenig       2  
  5.   Verken enig eller uenig       3  

. fre opp1n

opp1n
-------------------------------------------------------------------------------
                                  |      Freq.    Percent      Valid       Cum.
----------------------------------+--------------------------------------------
Valid   2 Uenig                   |          4      20.00      20.00      20.00
        3 Verken enig eller uenig |          8      40.00      40.00      60.00
        4 Enig                    |          5      25.00      25.00      85.00
        5 Veldig enig             |          3      15.00      15.00     100.00
        Total                     |         20     100.00     100.00           
-------------------------------------------------------------------------------

. fre opp1n, includelabeled 

opp1n
-------------------------------------------------------------------------------
                                  |      Freq.    Percent      Valid       Cum.
----------------------------------+--------------------------------------------
Valid   1 Veldi uenig             |          0       0.00       0.00       0.00
        2 Uenig                   |          4      20.00      20.00      20.00
        3 Verken enig eller uenig |          8      40.00      40.00      60.00
        4 Enig                    |          5      25.00      25.00      85.00
        5 Veldig enig             |          3      15.00      15.00     100.00
        Total                     |         20     100.00     100.00           
-------------------------------------------------------------------------------

[Namo Salih]

Thank you so much! I was really worried I would get stuck here. I appreciate the responses and again, thank you so much.