Misuse of forestplot

[Niels Henrik Bruun]

Hi
In many cases, I use the following code:

cls
webuse lbw, clear
regress bwt i.smoke##i.race
margins smoke#race
mata st_matrix("tbl", st_matrix("r(table)")[(1,5,6,4), .]')
matrix roweq tbl = non-smoker non-smoker non-smoker smoker smoker smoker
matrix rownames tbl = white black other white black other
matrix colnames tbl = b lb ub p
matrix2stata tbl, clear
rename tbl_* * 
strofnum eq names
meta set b lb ub, studylabel(names) random(mle)
meta forestplot _id _plot _esci, subgroup(eq) note("") nogmarkers noomarker ///
  noohetstats noohomtest noosigtest noghetstats nogwhomtests nogbhomtests ///
  columnopts(_id, title("")) columnopts(_esci, supertitle("mean weight")) /// 
  nooverall name(fig2, replace) nullrefline

to get a nice graph like:

What I can't figure out is the option to remove the summary rows (red dot in front) from the graph.
Does anyone know?

Thank you very much in advance.

[Tiago Pereira]

Niels, hi.

I would not use the random-effects ML weights. I would simply use the same weight for all estimates.

use http://www.stata-press.com/data/r10/lbw.dta, clear
regress bwt i.smoke##i.race
margins smoke#race
mata st_matrix("tbl", st_matrix("r(table)")[(1,5,6,4), .]')
matrix roweq tbl = non-smoker non-smoker non-smoker smoker smoker smoker
matrix rownames tbl = white black other white black other
matrix colnames tbl = b lb ub p
matrix2stata tbl, clear
rename tbl_* *
strofnum eq names
meta set b lb ub, studylabel(names) random(mle)
meta forestplot _id _plot _esci, subgroup(eq) note("") nogmarkers noomarker ///
  noohetstats noohomtest noosigtest noghetstats nogwhomtests nogbhomtests ///
  columnopts(_id, title("")) columnopts(_esci, supertitle("mean weight")) ///
   name(fig2, replace) nullrefline nometashow   overallopts(size(0))         
   
 
 forvalues i = 1/2 {
   
   
    gr_edit .plotregion1.column5.group_items[`i'].draw_view.setstyle, style(no)
    gr_edit .set_spositions
    gr_edit .set_graphwidth


    gr_edit .plotregion1.column6.group_items[`i'].draw_view.setstyle, style(no)
    gr_edit .set_spositions
    gr_edit .set_graphwidth
    

    gr_edit .plotregion1.column7.group_items[`i'].draw_view.setstyle, style(no)
    gr_edit .set_spositions
    gr_edit .set_graphwidth

}

[Niels Henrik Bruun]

Dear Tiago Thank you very much.
I had hoped that I could have avoided the use of gr_edit

[Andrew Musau]

What I can't figure out is the option to remove the summary rows (red dot in front) from the graph.
Does anyone know?

Those are controlled by the -groupopts()- option.

webuse lbw, clear
regress bwt i.smoke##i.race
margins smoke#race
mata st_matrix("tbl", st_matrix("r(table)")[(1,5,6,4), .]')
matrix roweq tbl = non-smoker non-smoker non-smoker smoker smoker smoker
matrix rownames tbl = white black other white black other
matrix colnames tbl = b lb ub p
matrix2stata tbl, clear
rename tbl_* * 
strofnum eq names
meta set b lb ub, studylabel(names) random(mle)
meta forestplot _id _plot _esci, subgroup(eq) note("") nogmarkers noomarker ///
  noohetstats noohomtest noosigtest noghetstats nogwhomtests nogbhomtests ///
  columnopts(_id, title("")) columnopts(_esci, supertitle("mean weight")) /// 
  nooverall name(fig2, replace) groupopts(color(none)) nullrefline

[Niels Henrik Bruun]

Excellent, thank you very much
But hey, then I loose the subgroup titles as well?

[Andrew Musau]

Yes, they are rendered together. I see no option to specify each separately.

[Niels Henrik Bruun]

Ok thank you

[David Fisher]

Just for interest's sake, here is one way to achieve a similar result using the user-contributed command metan (latest version v4.05 via SSC):

webuse lbw, clear
regress bwt i.smoke##i.race
margins smoke#race
mata: st_matrix("tbl", st_matrix("r(table)")[(1,5,6,4), .]')
matrix colnames tbl = b lb ub p
  
keep smoke race
duplicates drop
sort smoke race
svmat tbl, names(col)

metan b lb ub, study(race) by(smoke) effect(Mean weight) re(ml) nohet nowt nooverall nograph clear
label variable _LABELS ""
replace _LABELS = "" if _USE==3
replace _LABELS = "{tab}" + _LABELS if _USE==1
forestplot, useopts nonote nonull xlabel(2000(500)3500) range(2000 3633) ///
        olineopts(lcolor(none) lwidth(none)) diamopts(lcolor(none) lwidth(none)) ///
        classic boxsca(200)

[Niels Henrik Bruun]

David Fisher Nice