creating variable equal to count of number of unique values in a different variable, long panel data

[Tom Scott]

Hello,

I am trying to create a variable equal to the number of years of data available for each observation. I have a monthly dataset of agencies spanning 6 years. I used the following code but it's not working. There could be a way easier way of doing this too. Can anyone help me?

gen identifier = _n
levelsof identifier, local(identifierlvls)
gen numberofyears=.
foreach l of local identifierlvls {
    tab year if identifier==`l'
    matrix yearsmat`l' = r(r)
    replace numberofyears=yearsmat`l' if identifier==`l'
}

Thank you very much.

Tom

[Nick Cox]

You construct an identifier that is just 1 to the number of observations (subject to storage type; with a large data set some big integers can't be held exactly in a float). So by design each identifier occurs just once and your code if it worked would reflect exactly what you created.

A bug is that

 replace numberofyears=yearsmat`l' if identifier==`l'

needs to be

 replace numberofyears=yearsmat`l'[1,1] if identifier==`l'

But the creation of a matrix -- indeed matrices, one for each distinct identifier -- can be avoided, as code could be

  
 replace numberofyears= r(r) if identifier==`l'

As said, however, your code when fixed would record each identifier occurring once. Assuming an identifier id and a year variable year then

egen tag  = tag(id year)  

egen wanted = total(tag), by(id)

counts distinct values of year. If you don't have a year variable, then sing out and say exactly what your dates look like with a data example to get good advice. https://www.statalist.org/forums/for...s-in-a-dataset is another thread started today that seems to have the same answer.

[Tom Scott]

Nick Cox I had a year variable so your code

egen tag = tag(id year)

worked great and was obviously way easier. Thank you very much.