[Joseph Coveney]

The Treatment x Time interaction. I am not sure how this differs from my first two aims.

It doesn't. You fitted separate univariate regression models and tested the interaction terms separately. I fitted both together in a multivariate regression model and tested the interaction terms jointly..

. . . you mentioned before how "The likelihood-ratio test is of the Treatment × Time interaction. It is statistical evidence (confirmation) that the temporal profile of the outcome variables differs between treatment groups (exercise treatment versus control treatment)." Which is what we get from AIMS 1 and 2. Is that correct?

Yes. See immediately above.

The first graph you provided - it is completely random how participants recruited later are slightly older.

The graphs were tongue-in-cheek, sorry. Taking the two graphs together at face value, one could conjure that cognition improves monotonically with age. Now that's an interpretation that I could learn to like.

Also, the second graph you provided (participant accession number vs Flanker RT). I can't see how that would be a learning effect given how each participant is independent.

The learning effect that I was referring to is the downward trend in RT over the three sessions (more on this below). I wasn't referring to that graph.

But generally a bit unsure about the latent variable and how to write it up now.

1) It is a multivariate linear regression - DVs being MRI variables and Cognition . . .
2) one that accommodates the varying covariance and the longitudinal nature of the study (is there a specific name)?

I've seen expressions like "doubly multivariate repeated measures". You can Google that to see if there's anything more formal.

3) LR test - I think that is essentially the same as the mixed command?

Yes, evaluation of the treatment-by-time interaction. See above.

4) . . . is there also a way to say "changes in MRI correspond with changes in Cognition" overall in both groups - as an overall summary.

I'm not sure what you're trying to claim "in both groups": as mentioned above (learning effect), although there's an overall downward trend in all of the task scores over the three sessions in both treatment groups, it seems that MRI values didn't change very much in the control-treatment group between sessions. See the profile plots of sex- and age-adjusted outcomes below.

version 17.0

clear *

quietly input byte(pid trt sex) double age byte tim double(bmu sr) ///
    int(flanker_c_rt flanker_inc_rt stroop_c_rt stroop_inc_rt)
[elided for brevity]
end

label define Treatments 0 "Control" 1 "Experimental"
label values trt Treatments

label define Sexes 0 F 1 M
label values sex Sexes

label variable bmu "MRI Mu Score"

rename sr sim
label variable sim "Simon Task Score"

rename flanker_c_rt fcr
label variable fcr "Flanker Congruent RT"

rename flanker_inc_rt fir
label variable fir "Flanker Incongurent RT"

rename stroop_c_rt scr
label variable scr "Stroop Congruent RT"

rename stroop_inc_rt sir
label variable sir "Stroop Incongruent RT"

foreach var of varlist bmu-sir {

    quietly regress `var' i.trt##i.tim i.sex c.age
    quietly margins trt#tim

    if "`var'" == "bmu" local format %4.2f
    else if "`var'" == "sim" local format %03.1f
    else local format %3.0f

    local ytitle : variable label `var'

    if inlist("`var'", "bmu", "sim", "fcr") local xtitle
    else local xtitle Session

    quietly marginsplot , xdimension(tim) noci ///
        title("") legend(off) ///
        ytitle(`ytitle') ylabel( , format(`format') angle(horizontal) nogrid) ///
        xtitle("`xtitle'") ///
        plot1opts(lcolor(black) msymbol(none)) ///
        plot2opts(lcolor(black) lpattern(dash) msymbol(none)) ///
        name(`var')
    local graph_list `graph_list' `var'
}

graph combine `graph_list'
quietly graph export Summary.png, replace

exit