every sequence of rows replace for a certain value

[Marcela Vieira]

Hi everyone,

I generated a variable (gen perc=.) and would like to give it a certain value every few rows. Like the below:

perc

p10

p50

p90

p10

p50

p90

p10

p50

p90

I believe I have to do a loop, but couldn't find any similar example in the forum. Could you please help me with the code?

Thank you,

[Clyde Schechter]

No need for a loop:

gen perc = "p10" if mod(_n, 3) == 1
replace perc = "p50" if mod(_n, 3) == 2
replace perc = "p90" if mod(_n, 3) == 0

[Nick Cox]

Obfuscated code competition

gen perc = cond(mod(_n, 3) == 1, "p10", cond(mod(_n, 3) == 2, "p50", "p90"))

[William Lisowski]

Mathiest code competition.

gen perc = word("p90 p10 p50",1+mod(_n,3))

Added in edit: Now with addition and multiplication!

gen perc = "p"+string(10+40*mod(_n+2,3))

Where is Romalpa Akzo whose creatively elegant solutions are needed here?

[Romalpa Akzo]

Thanks, William Lisowski for your encouragement. Your first solution in #3 is my favourite. No solution could be more concise, I guess. The below code is just for fun, which shows that string could also be multiplicable in Stata.

gen perc3 = !mod(_n,3)*"p90" + !mod(_n+1,3)*"p50" + !mod(_n+2,3)*"p10"

[William Lisowski]

Thank you, that is amazingly novel. As usual, you see these problems from a perspective uniquely your own.