graph combine and making grids fit

[Niels Henrik Bruun]

Hi
I'm using the code:

cls
sysuse auto, clear

local x mpg
local y price
scatter `y' `x' , ///
    ylabel(0(5000)15000, grid) xlabel(10(5)45, grid) ///
    yscale(off) xscale(off) ///
    plotregion(lcolor(none) margin(zero)) ///
    name(yx, replace)
twoway histogram `y' , ///
    percent xscale(off) horizontal ///
    fxsize(25) fysize(100) ///
    plotregion(lcolor(none) margin(zero)) ///
    ylabel(0(5000)15000, grid) ///
    name(hy, replace)
twoway histogram `x' , ///
    percent yscale(off) ///
    fxsize(100) fysize(25) ///
    plotregion(lcolor(none) margin(zero)) ///
    xlabel(10(5)45, grid) ///
    name(hx, replace)
graph combine hy yx hx, hole(3) imargin(0 0 0 0)

to get the following graph:

My problem is that the vertical grids don't match.
Does anyone have a solution?

[Niels Henrik Bruun]

Found the solution myself: Just remove "fysize(100)" in the code above

[ericmelse]

Nice Niels,

But, I think also fxsize(100) has to be removed, at least at my system, the code now used is:

cls
sysuse auto, clear

local x mpg
local y price
scatter `y' `x' , ///
    ylabel(0(5000)15000, grid) xlabel(10(5)45, grid) ///
    yscale(off) xscale(off) ///
    plotregion(lcolor(none) margin(zero)) ///
    name(yx, replace)
twoway histogram `y' , ///
    percent xscale(off) horizontal ///
    fxsize(25) /// fysize(100)
    plotregion(lcolor(none) margin(zero)) ///
    ylabel(0(5000)15000, grid) ///
    name(hy, replace)
twoway histogram `x' , ///
    percent yscale(off) ///
    fysize(25) /// fxsize(100) 
    plotregion(lcolor(none) margin(zero)) ///
    xlabel(10(5)45, grid) ///
    name(hx, replace)
graph combine hy yx hx, hole(3) imargin(0 0 0 0)

Which results in:

[Niels Henrik Bruun]

ericmelse: thank you for noticing I actually did remove fxsize(100) as well. But it should also be clear in this forum.