use local in foreach command

[River Huang]

Dear All, I ran the following command

local in1 "inrange(year,2011,2012)"
local in2 "inrange(year,2009,2014)"

foreach v of local in1 in2 {
    reghdfe lPAY3 Treat Post Treat*Post if `v', a(stkcd year) vce(cl stkcd)           
}

but found the error message as

Does anyone know what's wrong with the code? Thanks.

[daniel klein]

The help file shows

foreach lname of local lmacname

meaning that foreach expects exactly one local macro name. You want

foreach inrange in in1 in2 {
    ... if ``inrange''
}

or

foreach inrange in "`in1'" "`in2'" {
    ... if `inrange'
}

[Raymond Zhang]

local in1 "inrange(year,2011,2012)"
local in2 "inrange(year,2009,2014)"

foreach v in `in1' `in2' {
    reghdfe lPAY3 Treat Post Treat*Post if `v', a(stkcd year) vce(cl stkcd)           
}

[daniel klein]

local in1 "inrange(year,2011,2012)"
local in2 "inrange(year,2009,2014)"

foreach v in `in1' `in2' {
reghdfe lPAY3 Treat Post Treat*Post if `v', a(stkcd year) vce(cl stkcd)
}

Raymond has essentially the same idea as #2. Note, however, that this code will fail if River includes spaces in the inrange() statements, which is legal syntax (and recommended by many style-guides):

. local in1 "inrange(year, 2011, 2012)"

. 
. foreach inrange in `in1'  {
  2.     display `"`inrange'"'
  3. }
inrange(year,
2011,
2012)

[Raymond Zhang]

Another way,

local in inrange(year,1935,1940) inrange(year,1941,1954)
foreach v of local in  {
    reghdfe invest mv ks  if `v', a(company year)           
}

[daniel klein]

Another way,

local in inrange(year,1935,1940) inrange(year,1941,1954)
foreach v of local in {
reghdfe invest mv ks if `v', a(company year)
}

Same caveat: beware of spaces.

[River Huang]

Dear daniel, Thanks, and it works.

[River Huang]

Dear Raymond, It works as well.

[Bjarte Aagnes]

local in1 inrange(year, 2011, 2012)
local in2 inrange(year, 2021, 2022)

local inx \`in1' \`in2'

foreach inrange of local inx {

    display "`inrange'"
}

[River Huang]

Dear Bjarte, Thanks for this additional, helpful suggestion. It works well.