Exporting multiple regressions with estout

[Jakob Smith]

Hello,

I have 10 regressions of the sort y =x1 + error term, y = x2 + error term .... y=x10+ error term. Y always being the same dependant variable. Now I would like to have the following output table:

	Coefficient (effect on y)	Standard error
x1
x2
x3
x4
x5
x6
x7
x8

I have not find a solution with estout that I usually use to compute nice output tables.

As always, thank you very much for your help!!

Jakob

[Andrew Musau]

estout is from SSC (FAQ Advice #12).

sysuse auto, clear
local coefs
foreach var in weight disp turn gear rep78{
    regress mpg `var'
    local coefs "`coefs' `var'"
    mat b = (nullmat(b), _b[`var'])
    mat se = (nullmat(se), _se[`var'])
}
mat res= b', se'
mat rownames res= `coefs'
mat colnames res= coefficient std_error 
esttab mat(res), substitute(std_error "std. error") mlabel(none)

Res.:

. esttab mat(res), substitute(std_error "std. error") mlabel(none)

--------------------------------------
              coefficient    std. error
--------------------------------------
weight          -.0060087     .0005179
disp            -.0444536     .0052606
turn            -.9457877     .1076853
gear             7.812835     1.176919
rep78            2.384298     .6628009
--------------------------------------

[Jakob Smith]

thank you so much. Works perfect