Suppressing "aobserved" in marginsplot?

[Joanna Kim]

Hello,

I want to plot an interaction between a binary variable (0 = control, 1 = treatment) and a categorical variable (0 = risk class 1, 1 = risk class 2, 2 = risk class 3). I am using margins and marginsplot and the plot comes out fine, except that I keep getting data for "aobserved." I can delete the aobserved data manually, but how do I suppress it from being printed in my graph using syntax? Example below.

Thank you for your help.

[Joanna Kim]

I should add that I am using Stata 16.1. Thank you!

[Andrew Musau]

In the future, create a reproducible example that exhibits your problem. You can suppress the "asobserved" plot as below:

webuse nhanes2f, clear
logit diabetes i.female##i.race weight height
set scheme s1color
margins i.female##i.race
marginsplot, xdim(race) saving(gr1, replace)
marginsplot, xdim(race) plot3opts(lc(none) mc(none)) ci3opts(col(none)) leg(order(4 "Male" 5 "Female")) saving(gr2, replace)
gr combine gr1.gph gr2.gph

Res.:

[Joanna Kim]

Thank you!

[Kim Lyngby Mikkelsen]

There is an easier way to suppress the "asobserved" from the marginsplot; you simply do not ask for them in you margins command!
In you margins command do not type i.a##i.b; - instead just type i.a#i.b !

Code:
sysuse auto.dta
gen displacement_gt_100= displacement>100
regress weight i.foreign##i.displacement_gt_100

margins foreign##displacement_gt_100
marginsplot, plot(displacement_gt_100 ) name(xx) ti(i.a##i.b)

Instead code:
margins foreign#displacement_gt_100
marginsplot, plot(displacement_gt_100 ) name(i.a#i.b)

xx.gph x.gph

[Kim Lyngby Mikkelsen]

regress weight age sex

[David Ibanez]

Dear Andrew,

If I want to make a triple interaction and I am using the option by(), how can I suppress the "asobserved"?

[Andrew Musau]

Just look at the plot position from the legend, where you count from the top column left=1, top-right =2 , second column top-left=3 and so on.

webuse nhanes2f, clear
qui sum weight, d
gen hiweight = weight> r(p50)
logit diabetes i.female##i.race##i.hiweight height
set scheme s1color
margins i.female##i.race##i.hiweight
marginsplot, xdim(race) saving(gr1, replace)

Res.:

So "as observed" plots are at positions 3, 6, 7, 8 and 9. Therefore, just repeat the options in #3 to suppress these plots.

marginsplot, xdim(race) plot3opts(lc(none) mc(none)) ci3opts(col(none)) ///
    plot6opts(lc(none) mc(none)) ci6opts(col(none)) ///
    plot7opts(lc(none) mc(none)) ci7opts(col(none)) ///
    plot8opts(lc(none) mc(none)) ci8opts(col(none)) ///
    plot9opts(lc(none) mc(none)) ci9opts(col(none)) ///
    leg(order(10 "Male low-weight" 11 "Male high-weight" ///
    13 "Female low-weight" 14 "Female high-weight" ))