Line graph (mean) with panel data

[Milena Schmidt]

Hey Stata community,

I tried to plot something using a panel data set and the "line" command (sales over time from 20 different companies).

Unfortunately, Stata shows me for each company separate lines. I just want to have 1 line over time (the mean of sales from all companies).

To demonstrate, I added a graph.

How can I see the mean line instead of 20 lines in the plot? Is there a mean-command that works?

Many thanks and best regards!

[William Lisowski]

Here's some sample code to run that demonstrates two approaches to getting a graph of mean values.

webuse pig
describe
// not means
graph twoway line weight week, name(g0)
// means, bars rather than line - but maybe better for you?
graph bar weight, over(week) name(g1)
// calculate means and graph as a line
preserve
collapse (mean) weight, by(week)
list
graph twoway line weight week, name(g2)
restore

[Milena Schmidt]

Thank you William, it worked!

[Nick Cox]

One reason why the graph in #1 is a mess is that you have spurious connections between the last value for one company and the first value for the next. You don't give your code, but I imagine it was something like

line Sales Year

This code for the pig data shows some technique, You can run this code, unless you are behind a major firewall.

webuse pig, clear
egen mean = mean(weight), by(week)
egen tag = tag(week)
line weight week, c(L) xla(1/9) lc(gs12) || line mean week if tag , ytitle(weight (units)) legend(order(2))

noting particularly

1. The c(L) option

2. Showing all the data as backdrop and a summary more prominently

In the case of your data, I wonder whether log scale would help and using a summary other than the mean, say the median or geometric mean. Naturally, the mean through its relation to the total may be informative too.

[Milena Schmidt]

Thanks Nick, I will try this!

[John Reynolds]

For the historical record, here is another approach using margins. Not as pretty or elegant as Nick's for sure.

webuse pig, clear
regress weight i.week
margins week
marginsplot, noci