Kakwani index Standard errors

[Aarushi Dhingra]

Hi,

I want to know how to obtain Kakwani index Standard errors, where Kakwani index is the concentration of health care payments minus the Gini coefficient.

Thanks,
Aarushi

[Felix Bittmann]

Unless there is an analytical formula available (infos from current literature?), the only thing that comes to my mind is bootstrapping which you could test (carefully) and see whether it makes sense.

[Aarushi Dhingra]

Felix Bittmann Thanks for that. There is a program called fastgini which helps calculate the Gini coefficient and jackknife std erros, using this I can perhpas progress.

[FernandoRios]

Hi Aarushi
I think you may have two options.
1 use bootstrap
2 use RIFS
Here an example code

cscript
use http://fmwww.bc.edu/RePEc/bocode/o/oaxaca.dta
set seed 1
gen wage= exp(lnwage)
drop if wage==.
sort wage
gen p=_n/_N
gen wage_t=wage*(1-(p+runiform())*.1)

** wage_t after tax wages

program bskw, eclass
sgini wage_t wage, sort(wage)
matrix kk = r(coeffs)
matrix kwindex=kk[1,1],kk[1,2], kk[1,1]-kk[1,2]
matrix colname kwindex = con_index gini kakwani
ereturn post kwindex
end
bootstrap:bskw

** via RIF
** Concentration
egen rif1=rifvar(wage_t), cindex(wage)
** gini
egen rif2=rifvar(wage), gini

gen rif3=rif1-rif2
mean rif1 rif2 rif3

HTH

[Aarushi Dhingra]

Hi Fernando,

This is great! Thank you much for your help. If you can please provide me with your correct details so I acknowledge you in my paper, if no that is ok too.

Kind Regards,
Aarushi

[Aarushi Dhingra]

I have a question FernandoRios, for the first option 'sort' is where you put the ranking variable? I have two variable out-of-pocket costs (oop) and household income (income), so sort wil be (income). Similarly, cindex will also include (income)
Sorry if this too basic!
Thank you in advance.

[FernandoRios]

HI Aarushi,
Yes, you are correct. In the first case, sort is where you put the ranking variable. And when using -rifhdreg-, you do that with the cindex() option.
Regarding reference, you can always cite my RIF paper
https://journals.sagepub.com/doi/pdf...36867X20909690
Best wishes
Fernando

[Aarushi Dhingra]

Great! Thank you so much.

Kind Regrads,
Aarushi