include x for FI for indep. var

[Caroline Christine]

Hi

I will like to include the number of FI in a tabel, when I estimate the model with fixed effects like this:

I usually use the command:

reghdge dep. var indep. var, absorb(i.origin) noconstant

eststo model_1

esttab model_1 using name.tex



So my question is: How do I get the last columns so i also include the number of fixed effects?

Thanks

[Andrew Musau]

reghdfe and estout are from SSC.

webuse grunfeld, clear
eststo m1: reghdfe invest mvalue kstock, a(company year)
ereturn list
mat list  e(dof_table)
estadd scalar ncompanies= e(dof_table)["1.company", "Categories"]
estadd scalar nyears= e(dof_table)["1.year", "Categories"]
esttab m1, drop(_cons) stats(N ncompanies nyears, labels("# observations" "#FE: firms" "#FE: years"))

Res.:

. esttab m1, drop(_cons) stats(N ncompanies nyears, labels("# observations" "#FE: firms" "
> #FE: years"))

----------------------------
                      (1)   
                   invest   
----------------------------
mvalue              0.118***
                   (8.56)   

kstock              0.358***
                  (15.75)   
----------------------------
# observat~s          200   
#FE: firms             10   
#FE: years             20   
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

[Caroline Christine]

thanks a lot!