Using scalar inputs and outputs in program

[Jae Yu]

I would like to generate a function that returns the degree of statistical significance with asterisks. The input of the function is p-value, scalar.

program drop _all
program ptosig, rclass
    args p
    if         `p'<=0.01    scalar s="***"
    else if `p'<=0.05     scalar s="**"
    else if `p'<=0.10     scalar s="*"
    else                 scalar s="."
    
    return scalar s= s
end

I would like to get * and *** when the input is 0.07 and 0.001, respectively.

ptosig 0.07
ptosig 0.001

My ultimate goal is to save the outcome of the program along with coefficients using postfile.
I'm new to stata, so any help would be appreciated.

[Leonardo Guizzetti]

Try this -- the change is to use local macros instead of scalars for strings when you wish to return them from a program.

cap program drop ptosig
program ptosig, rclass
    args p
    if      `p'<=0.01    local s="***"
    else if `p'<=0.05    local s="**"
    else if `p'<=0.10    local s="*"
    else                 local s="."
    
    return local s = "`s'"
end

ret list

That said, you probably don't need to do this if you are returning the p-value directly. It would be more natural afterwards to recode the values or better yet, generate a new categorization variable.

[Jae Yu]

Leonardo Guizzetti Thanks for your answer. It works very well. Could you elaborate a little more on "record the values"?

[Leonardo Guizzetti]

Sorry that should have read recode the values. I've way to do this in your postfile dataset would look like:

gen byte pvalue_group = .
replace pvalue_group = 3 if pvalue<0.01
replace pvalue_group = 2 if pvalue<0.05 & mi(pvalue_group)
replace pvalue_group = 1 if pvalue<0.1 & mi(pvalue_group)
label define stars 1 "*" 2 "**" 3 "***"
label values pvalue_group stars

or to generate stars:

gen stars = ""
replace stars = "***" if pvalue<0.01
replace stars = "**" if pvalue<0.05 & mi(stars)
replace stars = "*" if pvalue<0.1 & mi(stars)