Hausman Test issue: difference = 0 for every regressor

[George Smith]

I am dealing with panel data on 19 UK industries from 1997 to 2018. To test which estimator is most appropriate (pooled OLS / fixed effects / random effects), I run the following regressions.

regress log_y log_rdstock log_kl100000 im log_hc i.year, robust cluster(ID)
xtreg log_y log_rdstock log_kl100000 im log_hc i.year, fe cluster(ID)
xtreg log_y log_rdstock log_kl100000 im log_hc i.year, re cluster(ID)

The Breusch-Pagan test (xttest0) returns a p-value equal to 0. I then attempt to conduct a Hausman test using the following.

estimate store fe
estimate store re
hausman fe re, force

The difference (b - B) for each variable is reported as 0, and the Prob>chi2 is reported as "."

Can anyone explain why my Hausman test is producing these results, and how to amend the issue?

Thanks

[Carlo Lazzaro]

George:
I giess that nobody can help you if you do not share what Stata gave you back after -xtreg-, too (via CODE delimiters, please, as per FAQ). Thanks.

[Andrew Musau]

As Carlo Lazzaro states, you have to show exactly what you typed and the resulting Stata output (see FAQ Advice #12). Hazarding a guess, if you follow exactly the following sequence below, you are saving the same model twice and this will be consistent with your result. Note that hausman does not implement the robust version of the test, so if you are clustering your standard errors, look at xtoverid from SSC. Also, even without clustering your standard errors, do not include the year dummies as part of the test.

xtreg log_y log_rdstock log_kl100000 im log_hc i.year, fe cluster(ID)
xtreg log_y log_rdstock log_kl100000 im log_hc i.year, re cluster(ID)
estimate store fe
estimate store re
hausman fe re, force

What you should do instead:

xtreg log_y log_rdstock log_kl100000 im log_hc i.year, fe cluster(ID)
estimate store fe
xtreg log_y log_rdstock log_kl100000 im log_hc i.year, re cluster(ID)
estimate store re
hausman fe re, force

[George Smith]

Thank you Carlo and Andrew.

Andrew, I acted on your advice and ran the following.

xtreg log_y log_rdstock log_kl100000 im log_hc, fe cluster(ID)
estimate store fe
xtreg log_y log_rdstock log_kl100000 im log_hc, re cluster(ID)
estimate store re
hausman fe re, force

The Hausman test returned the following.

This seems like sufficient evidence to favour the random effects estimator over the fixed effects estimator. Would you agree?

Thanks

[Andrew Musau]

As I said in #3, you have clustered standard errors and therefore you cannot rely on results from hausman. If you type -help hausman-, you will find the following discussion:

Remarks

The assumption that one of the estimators is efficient (that is, has minimal asymptotic
variance) is a demanding one. It is violated, for instance, if your observations are
clustered or pweighted, or if your model is somehow misspecified.

Therefore install xtoverid from SSC and run the command after the random effects regression.

ssc install xtoverid
xtreg log_y log_rdstock log_kl100000 im log_hc, re cluster(ID)
xtoverid

A significant test statistic implies that you should opt for the fixed effects estimator.

[Eric de Souza]

To repeat what Andrew says in #5, by using the -force- option you are forcing performance of test, even though assumptions are not met ! (from the help file)
The hausman test is not valid when you cluster. What you are getting is gibberish.