Esport summary statistics by 5 groups

[Marco Errico]

Dear all,

Recfently I presented my research project to a faculty. One of the comment for improvement is related with descriptive statistics visualization.
Indeed, I presented my summary statistics by 5 groups in this way

Group1 _____Mean Std.dev
- var1
- var2
- var3
Group2
-var1
-var2
-var3

Nevertheless, they suggested me that it would be better to present in this way

________Group1 ________Group2
_______Mean. Std.dev__ Mean.Std.dev
var1
var2
var3


Do you have any suggestions on how to solve it?

[Scott Merryman]

Here is one way using -putdocx-:

sysuse auto,clear
 putdocx clear  
tabstat price mpg , by(fore) stat(mean sd)  nototal save
mat a = r(Stat1)
mat b = r(Stat2)
mat c = a' ,  b'
local n1 : variable label price
local n2 : variable label mpg
mat colnames c = "Mean" "Std. Dev." "Mean" "Std. Dev." 
putdocx begin
putdocx table mytable = matrix(c), nformat(%9.3f) rownames colnames
putdocx table mytable(1,.), addrows(1, before)
putdocx table mytable(1,2) = ("`=r(name1)'"), colspan(2) halign(center)
putdocx table mytable(1,3) = ("`=r(name2)'"), colspan(2) halign(center)
putdocx table mytable(3,1) = ("`n1'")
putdocx table mytable(4,1) = ("`n2'")
putdocx save mytable, replace

[Marco Errico]

Thank you, Scott!