how to extract the year from this date format

[Doris Rivera]

Dear all, I would like to ask for your assistance for extracting the year from the following date format 03jul2007 00:00:00 (see dataex below). I have tried using

gen yr1 = year(date)
gen yr2 = yofd(dofm(date))


generate double time=Clock(date,"DMY hms")
format time %tC

generate double newdate=date(date,"DMY hms")
format date %td

but they give all missing, or error "type mismatch". Any hint on how to do it?
Thanks for the help.

* Example generated by -dataex-. To install: ssc install dataex
clear
input double date
  1.49904e+12
1.5639264e+12
1.7614368e+12
1.7614368e+12
end
format %tc date

[Justin Niakamal]

gen year = yofd(dofc(date))

[Nick Cox]

Justin Blasongame gave a great answer, but what's left is why the answers in #1 are wrong.

 
 gen yr1 = year(date)

year() pulls years out of daily dates, but date is not a daily date, but a clock date-time.

gen yr2 = yofd(dofm(date))

dofm() pulls daily dates out of monthly dates, but date is not a monthly date.

generate double time=Clock(date,"DMY hms") format time %tC

Clock() pulls a clock date-time variable out of a string, but date already is such a variable, and the types mismatch, which is what Stata notices.

generate double newdate=date(date,"DMY hms") format date %td

date() pulls a daily date out of a string, but date already is numeric, and the types mismatch, which is what Stata notices.

[Doris Rivera]

Dear Justin and Nick, thanks a lot for your help. It worked perfectly, and thanks for the explanation, it is quite helpful.