Counting letters in Stata?

[Joaquin Gerring]

Hello

Maybe a weird question, but I can do

local i = 1
foreach x of numlist 1/10 {
  di `i'
  local i = `i' + 1
}

to count from 1 to 10 with i -- is there a simple way to do the same thing for letters? I.e. a simple way to have a macro containing only a letter take on the next letter in the alphabet?

Thanks
Jo

[Clyde Schechter]

forvalues j = 1/10 {
local letter = char(64+`j')
display `"`letter'"'
}

will "count" from A to J. Evidently if you go beyond 26, you are out of the Roman alphabet. If you wanted lower case letters, replace 64 with 96 in the above.

Or, perhaps more transparently:

forvalues j = 1/10 {
    local letter: word `j' of `c(ALPHA)'
    display `"`letter'"'
}

[Sven-Kristjan Bormann]

I am not sure what you want to achieve but the alphabet is stored in the system scalars c(alpha) and c(ALPHA)

creturn list
disp c(alpha)
disp c(ALPHA)

So you could modify your code to something like

forvalues i=1/10 {
local letters `letters' `=word(c(alpha),`i')'
}

[William Lisowski]

I'll add that an alternative to Clyde's code is

local nl 10
local list = substr("`c(alpha)'",1,2*`nl')
foreach letter of local list {
    display `"`letter'"'
}

which goes through the first nl letters of the alphabet.

[Nick Cox]

tokenize "`c(alpha)'"
forval j = 1/10 {
     di "``j''"
}

[Joaquin Gerring]

Thanks, this was great. To show what this is good for:

sysuse auto, clear
tokenize "`c(ALPHA)'"

local i 1
foreach x of varlist rep78 headroom trunk weight {
 di `i' _skip(5) "`x'"
 twoway scatter mpg `x', title("``i''") name("`x'", replace)
 local ++i
}
graph combine rep78 headroom trunk weight

[Nick Cox]

As in another thread https://www.statalist.org/forums/for...eady-in-memory crossplot and combineplot (SSC) do precisely that for you.