Removing trailing dashes in the string

[Anton Ivanov]

Hello!

I am extracting zip codes from the string variable called adr by using the following command:

generate zip = substr(adr,-5,.)

However, some of the strings have " -" in the end:

* Example generated by -dataex-. To install: ssc install dataex
clear
input str369 adr
"Mountain View Grand Resort & Spa 101 Mountain View Rd, Whitefield, NH 03598"    
"Weathervane Theatre 389 Lancaster Rd, Whitefield, NH 03598"                     
"Mountain View Golf Course 101 Mountain View Rd, Whitefield, NH 03598"           
"Mountain View Grand Resort & Spa 101 Mountain View Rd, Whitefield, NH 03598"    
"Silver Star Spa 6 W 48th St, New York, NY 10036 -"                              
"Red Robin Gourmet Burgers and Brews 18410 33rd Ave W, Lynnwood, WA 98036 -"     
"Guy's American Kitchen & Bar 220 W 44th St, New York, NY 10036 -"               
"Firestone Complete Auto Care 360 W St Georges Ave, Linden, NJ 07036 -"          
"Oasis Massage Salon 9889 Bellaire Blvd #331, Houston, TX 77036 -"               
"Northeast Pediatric Dentistry 11223 Davinci Dr, Davidson, NC 28036 -"           
"Righteous Movers 10333 Harwin Dr, Houston, TX 77036 -"                          
"Consulado Dominicano en Nueva York 1501 Broadway Floor 4r, New York, NY 10036 -"
end

How could I possibly drop these dashes and spaces?

Thankfully,
Anton

[Joseph Coveney]

Maybe something like the following.

generate str zip = strtrim(subinstr(substr(adr, -5, .), "-", "", .))

ETA: Sorry, I didn't notice that not all observations have the extra characters. You could modify the code above with something like this.

generate str zip = substr(strreverse(strtrim(subinstr(strreverse(adr), "-", "", .))), -5, .)

Or maybe use Stata's regular expression functions.

[William Lisowski]

This is most easliy handled with Stata's regular expression string functions, if you're comfortable with regular expressions. This will remove a trailing dash, as well as any blanks that precede or follow it.

replace adr = ustrregexrf(adr," *- *$","")

* Example generated by -dataex-. To install: ssc install dataex
clear
input str369 adr
"Mountain View Grand Resort & Spa 101 Mountain View Rd, Whitefield, NH 03598"  
"Weathervane Theatre 389 Lancaster Rd, Whitefield, NH 03598"                  
"Mountain View Golf Course 101 Mountain View Rd, Whitefield, NH 03598"        
"Mountain View Grand Resort & Spa 101 Mountain View Rd, Whitefield, NH 03598"  
"Silver Star Spa 6 W 48th St, New York, NY 10036"                              
"Red Robin Gourmet Burgers and Brews 18410 33rd Ave W, Lynnwood, WA 98036"    
"Guy's American Kitchen & Bar 220 W 44th St, New York, NY 10036"              
"Firestone Complete Auto Care 360 W St Georges Ave, Linden, NJ 07036"          
"Oasis Massage Salon 9889 Bellaire Blvd #331, Houston, TX 77036"              
"Northeast Pediatric Dentistry 11223 Davinci Dr, Davidson, NC 28036"          
"Righteous Movers 10333 Harwin Dr, Houston, TX 77036"                          
"Consulado Dominicano en Nueva York 1501 Broadway Floor 4r, New York, NY 10036"
end

To the best of my knowledge, only in the Statlist post linked here is it documented that Stata's new regular expression parser is the ICU regular expression engine documented at http://userguide.icu-project.org/strings/regexp.

[Anton Ivanov]

Joseph Coveney , William Lisowski thank you very much for your solutions. Issue solved.

[Joseph Coveney]

Thanks for the closure.

I'm not sure how I ended up with that overmuch line of code above.

generate str zip = substr(strtrim(subinstr(adr, "-", "", .)), -5, .)