t-test on coefficient of probit regression

[Leo Scaglione]

Hello there,
I'm trying to find the impact of contingencies on an explanatory variable in a probit regression. I've been told that using a t-test to compare the coefficients of the said variable on the different probit results (the standard one and the one with the contingency) is a good way to confirm my hypothesis, but I don't really know how to do that. Can somebody help me out?
PS Do you know other ways to verify this kind of relation?

[Clyde Schechter]

I wouldn't recommend doing this at all, but given that you've been directed to, here's an example of the code:

. sysuse auto, clear
(1978 Automobile Data)

. probit foreign mpg if rep78 <= 3

Iteration 0:   log likelihood = -10.655379
Iteration 1:   log likelihood = -9.0623342
Iteration 2:   log likelihood =  -8.956209
Iteration 3:   log likelihood = -8.9559877
Iteration 4:   log likelihood = -8.9559877

Probit regression                               Number of obs     =         40
                                                LR chi2(1)        =       3.40
                                                Prob > chi2       =     0.0652
Log likelihood = -8.9559877                     Pseudo R2         =     0.1595

------------------------------------------------------------------------------
     foreign |      Coef.   Std. Err.      z    P>|z|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
         mpg |   .1534275   .0909599     1.69   0.092    -.0248506    .3317056
       _cons |  -4.683941   2.047063    -2.29   0.022     -8.69611   -.6717727
------------------------------------------------------------------------------

. estimates store LE3

. probit foreign mpg if rep78 > 3

Iteration 0:   log likelihood = -23.331164
Iteration 1:   log likelihood = -22.155071
Iteration 2:   log likelihood =   -22.1517
Iteration 3:   log likelihood =   -22.1517

Probit regression                               Number of obs     =         34
                                                LR chi2(1)        =       2.36
                                                Prob > chi2       =     0.1246
Log likelihood =   -22.1517                     Pseudo R2         =     0.0506

------------------------------------------------------------------------------
     foreign |      Coef.   Std. Err.      z    P>|z|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
         mpg |   .0520696   .0349269     1.49   0.136    -.0163858     .120525
       _cons |  -1.061916   .8354725    -1.27   0.204    -2.699412    .5755804
------------------------------------------------------------------------------

. estimates store GT3

. suest LE3 GT3

Simultaneous results for LE3, GT3

                                                Number of obs     =         74

------------------------------------------------------------------------------
             |               Robust
             |      Coef.   Std. Err.      z    P>|z|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
LE3_foreign  |
         mpg |   .1534275   .0669031     2.29   0.022     .0222999    .2845551
       _cons |  -4.683941   1.399638    -3.35   0.001    -7.427182   -1.940701
-------------+----------------------------------------------------------------
GT3_foreign  |
         mpg |   .0520696   .0336403     1.55   0.122    -.0138642    .1180035
       _cons |  -1.061916   .8065989    -1.32   0.188    -2.642821    .5189892
------------------------------------------------------------------------------

. suest, coeflegend

Simultaneous results for LE3, GT3

                                                Number of obs     =         74

------------------------------------------------------------------------------
             |      Coef.  Legend
-------------+----------------------------------------------------------------
LE3_foreign  |
         mpg |   .1534275  _b[LE3_foreign:mpg]
       _cons |  -4.683941  _b[LE3_foreign:_cons]
-------------+----------------------------------------------------------------
GT3_foreign  |
         mpg |   .0520696  _b[GT3_foreign:mpg]
       _cons |  -1.061916  _b[GT3_foreign:_cons]
------------------------------------------------------------------------------

. test _b[LE3_foreign:mpg] = _b[GT3_foreign:mpg]

 ( 1)  [LE3_foreign]mpg - [GT3_foreign]mpg = 0

           chi2(  1) =    1.83
         Prob > chi2 =    0.1759

If you really want to find out "the impact of contingencies..." a t-test does not do that. You would be better off estimating the difference between the coefficients, along with the 95% CI of that difference. That would be an estimate of the impact; a t-test just gives you a (bogus, in my opinion) yes-no verdict on whether the impact is 0. If you want to get the difference and its CI, then instead of the -test- command above, run

. lincom _b[LE3_foreign:mpg] - _b[GT3_foreign:mpg]

 ( 1)  [LE3_foreign]mpg - [GT3_foreign]mpg = 0

------------------------------------------------------------------------------
             |      Coef.   Std. Err.      z    P>|z|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
         (1) |   .1013579   .0748845     1.35   0.176    -.0454131    .2481289
------------------------------------------------------------------------------

Added: Note also that -probit- does not produce t-statistics. It is a large sample estimator and gives z-tests. When -suest- combines them it takes that one step further and goes to a chi-square test.

[David Radwin]

If your contingency is adding one or more variables, and you want to evaluate the model itself (not a coefficient), you probably want a different test. See https://stats.idre.ucla.edu/stata/fa...test-in-stata/ for three options.