Create variable 0/1 based on other variables - error message

[Joe Tuckles]

Hi I want to create a new variable where the new variable has the value 1 if three other variables have the values 2 in either one of the three variables. In the new variable the value will be 0 if none of the three variables have a value of 2. The new variable will have a missing value if all of the variables has missing values.

I have tried the following code but got an error message:

generate var1=1 if smoking_a =2 & smoking_a !=. & smoking_b =2 & smoking_b !=. & smoking_c =2 & smoking_c !=.
invalid syntax
r(198);

[Carlo Lazzaro]

Joe:
what it my eyes is the missing double = sign after -if-:

 
 generate var1=1 if smoking_a==2 & smoking_a !=. & smoking_b==2 & smoking_b !=. & smoking_c==2 & smoking_c !=

[Joe Tuckles]

Hmm.. it seems every value is missing

[Carlo Lazzaro]

Joe:
as a second thought, you can also go -egen-:

. set obs 3
number of observations (_N) was 0, now 3

. gen A=2

. g B=2 in 2
(2 missing values generated)

. replace B=1 if missing(B)
(2 real changes made)

. g C=2 in 1/2
(1 missing value generated)

. replace C=1 if missing(C)
(1 real change made)

. egen flag=group(A B C)

. list

     +------------------+
     | A   B   C   flag |
     |------------------|
  1. | 2   1   2      2 |
  2. | 2   2   2      3 |
  3. | 2   1   1      1 |
     +------------------+

. g D=1 if flag==3
(2 missing values generated)

.

[Wouter Wakker]

Alternatively:

egen miss = rowmiss(smoking_*)
gen var1 = smoking_a==2 | smoking_b==2 | smoking_c==2 if miss!=3
drop miss
* OR
gen var1 = cond(smoking_a==2 | smoking_b==2 | smoking_c==2, 1, cond(missing(smoking_a) & missing(smoking_b) & missing(smoking_c), ., 0))

[Joe Tuckles]

Excellent all sorted!

[Jorrit Gosens]

Or, perhaps not shortest code, but perhaps most simplistically:

generate var1=0
replace var1=1 if smoking_a==2 | smoking_b==2 | smoking_c==2
replace var1=. if smoking_a==. & smoking_b==. & smoking_c==.

[Nick Cox]

Note that if a variable is 2 it is certainly not missing so conditions like

smoking_a == 2 & smoking_a !=.

just collapse to conditions like

  
smoking_a == 2