95% confidence intervals from pwcorr

[Sofia Oliveira]

Hello

I am running the following command in Stata:

pwcorr drug*, star(0.001) sig

Since I have 4 drugs this gives me a 4x4 table with correlations and p-values. Can someone help me with a basic question here: what test is Stata using to calculate this p-value?

And how to obtain 95% confidence intervals for each correlation?

Many thanks!

[Andrew Musau]

what test is Stata using to calculate this p-value?

Should be just a simple t-test where the null hypothesis is the correlation coefficient is equal to 0 against the alternative that it is significantly different from 0. The test statistic is

$$\text{t}= \frac{\hat{\rho} \sqrt{n-2}}{\sqrt{1-\hat{\rho}^2}}$$

where \(\hat{\rho}\) is the estimated correlation coefficient and \(n\) is the sample size.

clear
set obs 10
gen x1=_n
gen x2=x1
replace x2=1 in 9
pwcorr x1 x2, sig

*STATISTIC
di 0.6543*(sqrt(8))/(sqrt(1-(0.6543^2)))
*P-VALUE
di 2*ttail(8, abs(2.4471753))

Res.:

. clear

.
. set obs 10
number of observations (_N) was 0, now 10

.
. gen x1=_n

.
. gen x2=x1

.
. replace x2=1 in 9
(1 real change made)

.
. pwcorr x1 x2, sig

             |       x1       x2
-------------+------------------
          x1 |   1.0000
             |
             |
          x2 |   0.6543   1.0000
             |   0.0401
             |

. .
.
. di 0.6543*(sqrt(8))/(sqrt(1-(0.6543^2)))
2.4471753

.
. di 2*ttail(8, abs(2.4471753))
.04011306

[Sofia Oliveira]

Thank you very much Andrew for the explanation. Perfectly clear now.

Do you know how to calculate 95% CI for those correlations?


Many thanks!

[Richard Williams]

There are ancient routines ci2 and cii2 that claim to do it. findit ci2

Example:

. webuse nhanes2f, clear

. pwcorr weight height

             |   weight   height
-------------+------------------
      weight |   1.0000 
      height |   0.4777   1.0000 

. ci2 weight height, corr

Confidence interval for Pearson's product-moment correlation 
of weight and height, based on Fisher's transformation.
Correlation = 0.478 on 10337 observations (95% CI: 0.463 to 0.492)

It seem odd to me that built-in ci doesn't do it. You can read about the commands starting on p. 27 of

https://www.stata.com/products/stb/journals/stb59.pdf

[Joseph Coveney]

If you want to stick with official Stata commands, you could look into bootstrapping the confidence bounds. Something like

set seed `=strreverse("1519756")'

sysuse auto
bootstrap rho = r(rho), reps(400): corr displacement gear_ratio
estat bootstrap, all

You have to do the pairs individually, though.

[Sofia Oliveira]

Many thanks Richard and Joseph for your comments. It was very helpful!

[Mike Lacy]

Some tips on how to find information on such things in Stata:

1) "What formula is Stata using?" StataCorp is quite good about documenting such things. Try -help pwcorr-, and then click on the highlighted "View complete PDF manual entry." Near the top of the resulting PDF page you will see a link for "Methods and Formulas," which you can click on to jump to the formulas in the text.

2) When you have a "How do I do ... question, " trying searching in the command window using some of your key words. This won't always work, but in this case it leads to several possible add-on program of use: -search confidence interval correlation-

[Sofia Oliveira]

Makes sense - many thanks Mike for taking the time to share these tips.

[shem shen]

There are ancient routines ci2 and cii2 that claim to do it. findit ci2

Example:

. webuse nhanes2f, clear

. pwcorr weight height

| weight height
-------------+------------------
weight | 1.0000
height | 0.4777 1.0000

. ci2 weight height, corr

Confidence interval for Pearson's product-moment correlation
of weight and height, based on Fisher's transformation.
Correlation = 0.478 on 10337 observations (95% CI: 0.463 to 0.492)

It seem odd to me that built-in ci doesn't do it. You can read about the commands starting on p. 27 of

https://www.stata.com/products/stb/journals/stb59.pdf

Just in case anyone is interested, there seems to be a typo on p.28 (near bottom) of the document cited above:
the macro of the correlation value stored after running ci2 should be r(rho), not r(r).