stnet and median survival

[Laura Myles]

Hi Listers,

I am looking at the stnet command for net survival using Pohar Perme estimation. I would like to obtain median survival but I am unsure how to do so. Does it allow for post-estimation? should I be considering a different approach?

Thanks!

[Paul Dickman]

Using -stnet-, you simply identify (by looking at the table of estimates or a plot of the net survival function) the smallest time at which net survival is less than or equal to 0.5.

Alternatively, you could use -predict- following a fitted flexible parametric survival model (-stpm2-). The advantage is you also get a CI, but inference relies on fitting an appropriate model (whereas -stnet- is non-parametric).

Following is a simple illustration of both approaches (modified from the example in the Stata Journal article describing -stnet-). The estimated median net survival is around 3.8 years using -stnet- and 3.68 years using -stpm2-. The survival curve is very flat around the median (net survival is 0.5087 at t=3.5 years and 0.4831 at t=4.5 years) so a difference of this magnitude in the two estimated medians is not unexpected.

/***************************************************************************
Illustrates estimation of median net survival using 
-stnet- (non-parametric) and -stpm2- (Royston-Parmar model)

Both commands available from SSC
ssc install stnet
ssc install stpm2

Modified from the example shown in:
E. Coviello, P. W. Dickman, K. Seppä, and A. Pokhrel,
Estimating net survival using a life-table approach.
Stata Journal, 2015.

popmort.dta is available at https://pauldickman.com/data/popmort.dta

Paul Dickman, July 2019
***************************************************************************/
use https://pauldickman.com/data/colon_net, clear

stset exit, origin(dx) f(status) scale(365.24)

// Single life table for all patients
stnet using popmort ///
  if yydx>=1980 & yydx<1985, mergeby(_year sex _age) /// 
  breaks(0(.083333333)10) diagdate(dx) birthdate(birthdate) ///
  list(n d cns locns upcns secns) 

// Now fit a flexible parametric model for net survival
// First need to add the expected mortality rate at exit to the data
gen _age = min(int(age + _t),99)
gen _year = int(yydx + _t)
sort _year sex _age
merge m:1 _year sex _age using popmort,  keep(match master)

// Now fit the model
stpm2, df(5) scale(hazard) bhazard(rate)

// predict the median net survival (with 95% CI)
predict median in 1, centile(50) ci

list median* in 1

[Laura Myles]

Thanks Paul,

this is very helpful. Can I check that in the table produced by stnet, for the median value I pick 3.75 years which corresponds to a net survival of 0.4980?

Thanks again,
Laura

[Paul Dickman]

Yes, that's correct.

[Laura Myles]

Thanks for confirming.