Is there a way to access the values generated by the 'table' command?

[Ernestina delPiero]

Is there a way to access the values generated by the 'table' command and store it as a scalar for use in calculations.

For instance I want to use the means generated by this two-way table command which generates the mean of a third value (ie, apple_price):

table country state, c(mean apple_price n apple_price) format(%14.2fc)

A way to do this by creating a new variable is by calling:

bysort country state: egen groupmean_price= mean(apple_price)

..but then again, this requires creating a new variable.

[Clyde Schechter]

Unfortunately, the -table- command does not leave its results behind anywhere in memory. You have already uncovered a workaround using -egen, mean()-. To avoid creating new variables you could also do this:

levelsof country, local(countries)
foreach c of local countries {
    levelsof state if country == "`c'", local(states)
    foreach s of local states {
        summ apple_price if country == "`c'" & state == "`s'", meanonly
        scalar mean_`c'_`s' = r(mean)
        scalar n_`c'_`x' = r(N)
    }
}

Note: Assumes country and state are string variables. If not, modify accordingly.

[Weverthon Machado]

Another workaround is using -xtable- command with the -noput- option, which will store the output in r(xtable) (see: https://www.statalist.org/forums/for...utput-to-excel). You can then access the values with matrix indices:

xtable country state, c(mean apple_price n apple_price) format(%14.2fc) noput

mat list r(xtable)
mat results = r(xtable)
di results[1,1]

[Sergiy Radyakin]

Ernestina delPiero , see option replace of the table command.

[David Radwin]

Another workaround is temporary variables:

tempvar groupmean_price
bysort country state: egen `groupmean_price' = mean(apple_price)