Interpretation of Chow test

[Lewis Makosa]

Hi guys, I am new on Stata and also a non native English speaker. I have been learning Stata on my own through watching various videos on youtube and reading different posts on different websites. Currently I am stuck on how to interpret chow test, I have read different posts including https://www.stata.com/support/faqs/s...how-statistic/ , https://www.stata.com/support/faqs/s...cs/chow-tests/ but i am failing to understand the interpretation of the results.

For an example, after calculating Chow test, another author found this.....The Chow test is F(k,N_1+N_2-2*k) = F(3,174), so our test statistic is F(3,174) = 5.0064466. According to his final results I failed to understand if the grouping of 2 groups is justified or not.

perhaps I am failing to understand because of my poor level of English.

Please can someone help me in simple English how to interpret Chow test or to tell if the data is justified to be separated into 2 groups.

[Phil Bromiley]

You didn't get a quick answer. You'll increase your chances of a useful answer by following the FAQ on asking questions - provide Stata code in code delimiters, readable Stata output, and samp[e data using dataex. You will also benefit from a good grounding in statistics (of whatever flavor your discipline embraces).

A Chow test tests whether two sets of parameters are equal, or equivalently, whether allowing separate parameters improves fit sufficiently. A significant test suggests the parameters differ.

[Lewis Makosa]

You didn't get a quick answer. You'll increase your chances of a useful answer by following the FAQ on asking questions - provide Stata code in code delimiters, readable Stata output, and samp[e data using dataex. You will also benefit from a good grounding in statistics (of whatever flavor your discipline embraces).

A Chow test tests whether two sets of parameters are equal, or equivalently, whether allowing separate parameters improves fit sufficiently. A significant test suggests the parameters differ.

Thanks for reply, i will soon provide the information you have mentioned.

[Richard Williams]

These handouts may be helpful. At one extreme, all coefficients are equal across groups. More common is to allow the intercepts to differ but not the slopes. Then, you can allow one or more slopes to differ, but not all of them. Finally, everything, both intercepts and slopes, is free to differ.

https://www3.nd.edu/~rwilliam/stats2/l51.pdf

https://www3.nd.edu/~rwilliam/stats2/l52.pdf

[Bruce Weaver]

A Chow test tests whether two sets of parameters are equal, or equivalently, whether allowing separate parameters improves fit sufficiently. A significant test suggests the parameters differ.

In Psychology and related fields, this is sometimes called Potthoff analysis, after Potthoff (1966). My colleague Karl Wuensch has some notes on it on his website.

[Bruce Weaver]

After realizing that the Chow test and Potthoff analysis are the same thing, I was moved to cobble together this example.

// Chow Test FAQ example from:
// https://www.stata.com/support/faqs/statistics/chow-tests/

// "A Chow test is simply a test of whether the coefficients estimated
// over one group of the data are equal to the coefficients estimated
// over another, and you would be better off to forget the word Chow and
// remember that definition."

// This is exactly the same thing "Potthoff analysis" does.  
// E.g., see these notes by Karl Wuensch:
// http://core.ecu.edu/psyc/wuenschk/MV/multReg/Potthoff.pdf.

// Start with the main bits of code from William Gould's FAQ

clear *
sysuse auto
generate group1=rep78==3
generate group2=group1==0

regress price mpg weight if group1==1
regress price mpg weight if group2==1

generate mpg1=mpg*group1
generate weight1=weight*group1

generate mpg2=mpg*group2
generate weight2=weight*group2

regress price group1 mpg1 weight1 group2 mpg2 weight2, noconstant
test _b[mpg1]=_b[mpg2], notest
test _b[weight1]=_b[weight2], accum notest
test _b[group1]=_b[group2], accum


// Now do Potthoff analysis using -nestreg-
// -nestreg- doesn't take factor variables,
// so we must compute our own product terms.

generate GRP1xMPG = group1*mpg
generate GRP1xWT = group1*weight

nestreg: regress price (mpg weight) (group1 GRP1xMPG GRP1xWT)
// Notice that the F-test on the change in R^2 matches the
// result from William Gould's -test- above.

// We can also estimate the two regression models using
// factor variables, store the estimates for each one,
// and compare the models via Maarten L. Buis's -ftest- command.
// net describe ftest, from(http://fmwww.bc.edu/RePEc/bocode/f)

quietly regress price group1##(c.mpg c.weight)
estimates store model2
quietly regress price mpg weight if e(sample)
estimates store model1
ftest model1 model2

PS- I'm disappointed to see that -nestreg- still cannot take factor variables in version 16. I'll add this to the version 17 wish list.