Drop base variables from fvexpand list

[Richard Williams]

I want to modify the variable list produced by fvexpand, e.g.

. webuse nhanes2f, clear

. fvexpand i.sex i.race

. return list

macros:
              r(fvops) : "true"
            r(varlist) : "1b.sex 2.sex 1b.race 2.race 3.race"

I want to drop the base category variables from r(varlist), in this case 1b.sex and 1b.race. Is there any easy way to do this? The base category variables are causing problems with another program of mine (they aren't getting dropped like they should) so I want to see if this will solve my problem.

[Clyde Schechter]

I don't know of any elegant way, but brute force elimination works:

webuse nhanes2f, clear

fvexpand i.sex i.race

return list

local full_list `r(varlist)'
local reduced_list
foreach t of local full_list {
    if strpos("`t'", "b.") == 0 {
        local reduced_list `reduced_list' `t'
    }
}

display `"`reduced_list'"'

[daniel klein]

Probably not much of an improvement, since a loop is still needed, but I think this is the (undocumented) tool used by StataCorp.

webuse nhanes2f, clear

fvexpand i.sex i.race
local full_list `r(varlist)'

local reduced_list
foreach t of local full_list {
    _ms_parse_parts `t'
    if (r(base)) continue
    local reduced_list `reduced_list' `t'
}

display "`reduced_list'"

Best
Daniel

[Richard Williams]

Thanks Clyde and Daniel! _ms_parse_parts is one of those weird undocumented commands that are documented . You can read about it via

help _ms_parse_parts

It turns out this may not actually solve the bigger problem I am having but I will keep playing around with it.

[FernandoRios]

For anyone arriving at this post.
I recently found out that within the community contributed package "ftools", there is a command "ms_fvstrip" that does exactly this.
Best Regards
Fernando