intraclass correlation error message

[Nina Palker]

I am trying to calculate intraclass correlation using a two way random effects model for a test retest reliability calculation. A sample of my data are attached below. I had 11 raters and the time variable represents the two time points on which the data were collected. I am getting this error message "multiple observations per target and rater not allowed" when I use the syntax
icc outcome id rater

[Joseph Coveney]

For that command, I think that you need to have each rater judge each target just once. From the display, I cannot tell whether you have each rater-target combination, which would be ideal for a cross-classified random-effects model.

You seem to have binary ratings, wouldn't you want to use something like meprobit, anyway?

version 15.1

clear *

set seed `=strreverse("1490389")'

quietly set obs 11
generate byte rater = _n
generate double rater_u = rnormal()

tempfile raters
quietly save `raters'

drop _all
quietly set obs 107
generate int target = _n
generate double target_u = rnormal()

cross using `raters'

quietly expand 2
bysort rater target: generate byte time = _n

generate double xb = rater_u + target_u
generate byte outcome = xb + rnormal() > 0

*
* Begin here
*
meprobit outcome i.time || _all: R.target || rater: , nolrtest nolog

tempname V_target V_rater
scalar define `V_target' = _b[/var(_cons[_all>target])]
scalar define `V_rater' = _b[/var(_cons[rater])]

display in smcl as text %04.2f `V_target' / (1 + `V_target' + `V_rater')

exit