Recoding household relationships in a census based on women aged 15-49 in a household

[Tatenda Mugwendere]

Dear Statalist Members!

I am using STATA 12.1 and working with the person file of a household census. My aim is to reclassify the 14 categories of relationships to head in the census, based on women aged 15-49 in that particular household as the unit of reference. I want to ascertain the living arrangements of this group of interest, whether they live with people from their own generation (e.g Brother, Sister) and/or people from the previous generation (e.g Parent, Uncle, Aunt). What i first did was create dummy variables for all the household relation categories to head which show whether or not a woman aged 15-49 years was present/absent in a household. For ease of explanation i am going to use 1 household category (Son/Daughter), the code i used to establish the presence of a woman in a household in this category was through creation of a variable 'daughter.'

by SN, sort: gen house=.
replace house=1 if P02_RELATION==3 & F03_SEX==2 & F02_AGE>=15 & F02_AGE<=49
replace house=0 if (P02_RELATION==3 & F03_SEX==2 & F02_AGE<15 | F02_AGE>49) | (P02_RELATION==3 & F03_SEX!=2) | P02_RELATION!=3 
egen daughter=max(house), by( SN)
browse SN P02_RELATION F03_SEX F02_AGE daughter 
label variable daughter "Head's daughter aged 15-49 years present in H/hold"
label define daughter 1"Present" 0"Absent"
label values daughter daughter

In households where daughters were present, i created another variable 'relation_daughter' which captures how the rest of the household is related to the daughter of the head

generate relation_daughter=.
replace relation_daughter=1 if daughter==1 & P02_RELATION==1
replace relation_daughter=2 if daughter==1 & P02_RELATION==2   
replace relation_daughter=3 if (daughter==1 & P02_RELATION==3 & F03_SEX==1) | (daughter==1 & P02_RELATION ==4)
replace relation_daughter=4 if daughter==1 & P02_RELATION==5
replace relation_daughter=5 if daughter==1 & (P02_RELATION==6|P02_RELATION==11)
replace relation_daughter=6 if daughter==1 & (P02_RELATION==7|P02_RELATION==8)
replace relation_daughter=7 if daughter==1 & P02_RELATION==9 & P14A_MOTHERPNR!=98 & P14A_MOTHERPNR!=.
replace relation_daughter=8 if daughter==1 & P02_RELATION==9 & (P14A_MOTHERPNR==98 |P14A_MOTHERPNR==.)
replace relation_daughter=9 if daughter==1 & P02_RELATION==10 & F03_SEX==1
replace relation_daughter=10 if daughter==1 & P02_RELATION==10 & F03_SEX==2
replace relation_daughter=11 if daughter==1 & P02_RELATION==12
replace relation_daughter=12 if daughter==1 & P02_RELATION==13
replace relation_daughter=13 if daughter==1 & P02_RELATION==14
label variable relation_daughter "Relation to daughter"
label define relation_daughter 1"Father/Mother" 2"Mother/Father or Stepfather/mother" 3"Brother/Sister" 4"Stepsibling" 5"Uncle/Aunt" 6"Grandmother/Father or Step Grandparent" 7"Son/Daughter or Nephew/Niece" 8"Nephew/Niece or Grandson/daughter" 9"Husband or Brother-in-law" 10"Sister-in-law" 11"Great-grandmother/Father" 12"Other relative" 13"Non-related person"
label values relation_daughter relation_daughter
tab relation_daughter

In the given household, relation_daughter shows how everyone else would be related to her if she was the unit of reference.

* Example generated by -dataex-. To install: ssc install dataex
clear
input double SN int(F00_NR F02_AGE) byte(F03_SEX P02_RELATION P14A_MOTHERPNR P15A_FATHERPNR) float(daughter relation_daughter)
10000010084 1 49 1  1  .  . 1  1
10000010084 2 44 2  2 98  . 1  2
10000010084 4 17 1  3  2  1 1  3
10000010084 3 18 2  3  2  1 1  .
10000010084 5 11 1  3  2  1 1  3
10000010084 6  0 1  9  3 98 1  7
10000010084 7 24 2 13 98 98 1 12
10000010084 8 18 1 13 98  . 1 12
end
label values F03_SEX F03_SEX
label def F03_SEX 1 "1. Male", modify
label def F03_SEX 2 "2. Female", modify
label values P02_RELATION P02_RELATION
label def P02_RELATION 1 "1. Head/Acting head", modify
label def P02_RELATION 2 "2. Husband/wife/partner", modify
label def P02_RELATION 3 "3. Son/daughter", modify
label def P02_RELATION 9 "9. Grand/greatgrand child", modify
label def P02_RELATION 13 "13. Other relative", modify
label values P14A_MOTHERPNR P14A_MOTHERPNR
label def P14A_MOTHERPNR 98 "98. Mother not in the household", modify
label values P15A_FATHERPNR P15A_FATHERPNR
label def P15A_FATHERPNR 98 "98. Father not in the household", modify
label values daughter daughter
label def daughter 1 "Present", modify
label values relation_daughter relation_daughter
label def relation_daughter 1 "Father/Mother", modify
label def relation_daughter 2 "Mother/Father or Stepfather/mother", modify
label def relation_daughter 3 "Brother/Sister", modify
label def relation_daughter 7 "Son/Daughter or Nephew/Niece", modify
label def relation_daughter 12 "Other relative", modify

My issues are 1) I would have preferred a way of recoding that would have shown who the daughter lived with without me having to pull out the household because it gets messy with many categories and variables, how best can i do that? 2)There are cases of 2 or more daughters in a household who meet the criteria, how can i code them separately

[Mike Lacy]

You had said:

>I am using STATA 12.1 and working with the person file of a household census. My
>aim is to reclassify the 14 categories of relationships to head in the census,
>based on women aged 15-49 in that particular household as the unit of reference.

I find this confusing: Is the head of household the "ego" in relation to which all
other "alters" are to be related, or is a woman aged 15-49 the centering point?
For me, you would need to better explain what distinct role such women play in
your plans. "Unit of reference" does not have a particular meaning for me.

>I want to ascertain the living arrangements of this group of interest,
What do you mean by "group of interest." Do you mean: "I want to characterize
each individual by their relation to the head of household, and compare
individuals who are women 15-49 vs. other persons?"

> What i first did
>was create dummy variables for all the household relation categories to head
>which show whether or not a woman aged 15-49 years was present/absent in a
>household. For ease of explanation i am going to use 1 household category
>(Son/Daughter), the code i used to establish the presence of a woman in a
>household in this category was through creation of a variable 'daughter.'

I understand this even less than the preceding. You need to 1) Show your description to a colleague, and get her/his help in offering a description that will speak more precisely to other people; 2) Tell us what each of your variable names in your example means. I'd think of those two things as good steps to your presenting a question we will be able to understand and therefore help with.

[Tatenda Mugwendere]

Thanks Mike

My apologies for the lack of clarity. What i want to do is create an index for women (15-49 years) which tells me who they live with in their households using census data. The census only classifies household relationships based on how members are related to the household head using the P02_RELATION variable which has 14 categories (Head, Husband/Wife/Partner, Son/Daughter, Brother/Sister and so-on). So for example if a household has three people coded as Head, Husband/Wife/Partner, Son/Daughter and the last two are females aged between 15 and 49, i would like to show that in this household, Wife/Partner stays with her husband (coded as head) and daughter (or stepdaughter) (coded as Son/Daughter), I also want to show that the daughter stays with her Father (Coded as head) and possibly her mother (Coded as Husband/Wife/Partner), I establish whether or not the Wife/Partner of the Head is the daughter's mother using the mother's person number variable P14A_MOTHERPNR. In this example, my interest is in the 2 women aged 15-49 and showing how they are related to the rest of the household. I can only do this by reclassifying relationships in the household so that they are based on them and not the household head. So with census data, i want to recode the relationships provided which are based on household head so that they are based on women aged 15-49 who live in those households. My first task was to establish how women aged 15-49 are coded by the P02_RELATION variable and then identify the households they live in so that i can be able to recode all the relationships based on them. Of the 14 relationship categories provided by the P02 variable, i won't be able to ascertain the living arrangements of those who were classified as Other relatives and Non-related, its difficult to work out how they are related to the rest of the household given that little information. It will also be difficult to ascertain how women captured by the other 12 categories relate to people classified as Other relatives or Non-related to Head of household.

What i was trying to say in the first post was, i first created dummy variables for the 12 available relationship categories in P02_RELATION (excluding those classified as Other relatives or Non-related), to see if women aged between 15 and 49 classified by these categories were present or absent in a household. The example i gave was based on the dummy variable i had created for those coded as Son/Daughter. The dummy variable 'daughter' establishes whether or not in a household there is a woman aged between 15-49 coded under the Son/Daughter category. If present i then recode the relationships in that household based on how everyone in that household is related to the daughter. In my example the variable i created to recode relationships in that household was 'relation_daughter'.
The variables i have used are defined as follows
SN - Household Serial Number
F00_NR- Person number
F02_AGE - Age in completed years
F03_SEX - Sex
P02_RELATION- Relationship to Household head
P14A_MOTHERPNR - Mother's Person Number
P15A_FATHERPNR - Father's Person Number
daughter - If a woman aged 15-49 classified as Son/Daughter is present in a household
relation_daughter - Relationship of household members to daughter

My issues are 1)I would have preferred a way of recoding that would have shown who the daughter lived with without me having to pull out the entire household because it gets messy with many categories and variables, how best can i do that? and 2) There are cases of 2 or more daughters in a household who meet the criteria (Female and aged between 15-49), how can i code them separately?

Hope that's clearer

Regards
Tatenda

[Mike Lacy]

I'm sorry, but I still don't understand you. I think that part of the difficulty is that you construe the problem as involving women 15-49, and that confuses how you think about and describe your problem. In a program like Stata, you would think of creating a variable that characterizes any and all persons in the sample. You may well have particular interest in only a subset of your persons (observations), but that fact is (likely) irrelevant to your computer code. A further difficulty is that as given above, your description is tied together with the methods you have tried to use to create what you want, which sometimes helps, but in this case happens to be confusing.

I think your goal can be more simply stated as: "I want to have a variable that categorizes each person in my sample according to a set of household relational categories that are different than those used in the variables supplied with the data set. The variables I currently have are as follows ..." To do this, it would help to have a *simple* list of:

1) the categories that you want for this new variable, their coding and description. Part of that is buried somewhere in your description, but it's hard to dig it out.
2) the variables that you currently have for each person in the household, their coding, and description.

Your description will likely be clearer if you forget about any references to "women 15-49," and simply rely on the fact that if, for example, I am a 20 year old male, I'm not going to fall into the category "widowed grandmother living with children." I understand that the categories that you have chosen will be ones that are optimal for characterizing the situations of women 15-49, but that's a different issue.

Again, I would suggest strongly that you show your description to someone else before posting it again. I always find that a face-to-face discussion of this sort of thing helps me make my description more clear.

[David Benson]

Hi Tatenda,

1) I think I know what you want to do, but won't have time to respond to this today. However, I would take a look at the following posts that may be helpful: see here , here, and here.

2) Also, could you provide 4-5 more households using dataex (just like you did in post #1) -- it makes it easier to see the variety of situations to handle.

[David Benson]

Tatenda, when you are done, do you want a dataset that looks like this (and includes *only* the women age 18-49 )? And then run some regression for these women measuring how with whom they live affects measures like earnings, educational attainment, or life satisfaction (or something like that)?

* I created a toy dataset
* Example shared via -dataex-. To install: ssc install dataex
clear
input byte(id hhid female age lives_with_father lives_with_mother other_prior_gen lives_with_sibling lives_with_spouse)
 1 1 1 24 1 0 0 1 0
 2 1 1 22 1 0 0 1 0
 3 2 1 23 0 1 1 1 0
 4 2 1 21 0 1 1 1 0
 5 3 1 42 0 0 0 0 0
 6 4 1 37 0 0 0 0 1
 7 5 1 31 0 0 0 0 1
 8 6 1 32 0 0 0 0 1
 9 7 1 34 0 0 1 0 0
10 8 1 23 1 1 1 1 0
end
------------------ copy up to and including the previous line ------------------

. list, sepby(hhid) abbrev(18) noobs

  +-----------------------------------------------------------------------------------------------------------------------------+
  | id   hhid   female   age   lives_with_father   lives_with_mother   other_prior_gen   lives_with_sibling   lives_with_spouse |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  1      1        1    24                   1                   0                 0                    1                   0 |
  |  2      1        1    22                   1                   0                 0                    1                   0 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  3      2        1    23                   0                   1                 1                    1                   0 |
  |  4      2        1    21                   0                   1                 1                    1                   0 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  5      3        1    42                   0                   0                 0                    0                   0 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  6      4        1    37                   0                   0                 0                    0                   1 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  7      5        1    31                   0                   0                 0                    0                   1 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  8      6        1    32                   0                   0                 0                    0                   1 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  |  9      7        1    34                   0                   0                 1                    0                   0 |
  |-----------------------------------------------------------------------------------------------------------------------------|
  | 10      8        1    23                   1                   1                 1                    1                   0 |
  +-----------------------------------------------------------------------------------------------------------------------------+

A few things:
1) Here I broke out whether the mother or father was in the home (and I was thinking of other_prior_gen as aunts, uncles, or grandparents)
2) I made id==1 & 2 a set of sisters living with their father. ID==3 & 4 are sisters living with their mother (and an aunt or something)
3) I named the var for "living with people from their own generation (e.g Brother, Sister)" as lives_with_sibling. I didn't know if you wanted a separate lives_with_sister, lives_with_brother (or if they had cousins living in the household)
4) ID==8 I was envisioning someone living with roommates. (If they are of the same generation, I didn't know if that qualified under rule #3.)
5) How did you want to code if the 18-49 had children (and they were living with her.)?

[Tatenda Mugwendere]

Thanks Mike for your help. I think David understands my line of thought better. David, i read the posts you directed me to and i think the first one about Mother in law is closely related to what i want to do. Thanks for the demonstration using the toy dataset, that is the sort of outlay i want to produce, taking a leaf from what you have done the extra columns (variables) i want to create would be labelled as lives_with_spouse, lives_with_father, lives_with_mother, lives_with_child, lives_with_sibling, lives_with_nephew/niece, lives_with_grandchild, lives_with_parentinlaw, other_own_gen, other_previous_gen and unclassifiable.
Those captured by the other_own_gen would be brother/sister in law, other_previous_gen would capture people like Uncle/Aunt/Grandparents, and unclassifiable would be for those coded as other relatives or non-related by the P02_RELATION variable. The P02_RELATION variable provided by the census shows how household members are related to the household head only, and has the following categories:
1) Head/Acting Head
2) Husband/Wife/Partner
3) Son/Daughter
4) Adopted Son/Daughter
5) Stepchild
6) Brother/Sister
7) Parent (Mother/Father)
8) Parent-in-law
9) Grand/Great grandchild
10) Son/daughter in law
11) Brother/Sister in law
12) Grandmother/Father
13) Other relative
14) Non-related person
The women aged 15-49 (my group of interest) have been classified by these 14 categories in the different households they live in. So i want to recode their relationships with other household members so that in the end i have a dataset for only women aged 15-49 and their household relations being classified by those 11 italicized variables. I am including a dataset with five different households, and the way females (15-49) are classified in those households vary between Head/Acting Head, Husband/Wife/Partner, Son/Daughter, Brother/Sister, Parent (Mother/Father) and Grand/Great grandchild. Question is how do i represent them using those 11 categories i intend to create?

* Example generated by -dataex-. To install: ssc install dataex
clear
input double SN int(F00_NR F02_AGE) byte(F03_SEX P02_RELATION P03_MARITAL_ST P04_SPN P14A_MOTHERPNR P15A_FATHERPNR)
10043973491 1 63 2  1 3  .  .  .
10043973491 2 23 2  9 3  . 98 98
10043973491 3 18 1  9 3  . 98 98
10043973491 4  3 1  9 3  .  2 98
10009101506 1 29 1  1 1  2 98 98
10009101506 2 22 2  2 1  1 98 98
10009101506 3  7 2  3 3  .  2  1
10009101506 4  2 1  3 3  .  2  1
10009101506 5  8 2  3 3  .  2  1
10043973297 1 52 2  1 1 98  .  .
10043973297 2 31 2  3 3  .  1  .
10043973297 3 16 2  3 3  .  1  .
10043973297 4  3 2  9 3  .  2 98
10043973297 5  0 1  9 3  .  3 98
10009775656 1 37 2  1 3  .  .  .
10009775656 2 21 2 14 3  . 98 98
10009775656 3 15 2  3 3  . 98  .
10009775656 4 16 2  6 3  . 98 98
10009775656 5 19 1  3 3  . 98 98
10009775656 6  0 1  9 3  .  2 98
10026742411 1 25 2  1 3  .  3 98
10026742411 2  1 1  3 3  .  1  .
10026742411 3 49 2  7 3  . 98  .
end
label values F03_SEX F03_SEX
label def F03_SEX 1 "1. Male", modify
label def F03_SEX 2 "2. Female", modify
label values P02_RELATION P02_RELATION
label def P02_RELATION 1 "1. Head/Acting head", modify
label def P02_RELATION 2 "2. Husband/wife/partner", modify
label def P02_RELATION 3 "3. Son/daughter", modify
label def P02_RELATION 6 "6. Brother/sister", modify
label def P02_RELATION 7 "7. Parent (Mother/father)", modify
label def P02_RELATION 9 "9. Grand/greatgrand child", modify
label def P02_RELATION 14 "14. Non related person", modify
label values P03_MARITAL_ST P03_MARITAL_ST
label def P03_MARITAL_ST 1 "1. Married", modify
label def P03_MARITAL_ST 3 "3. Never married", modify
label values P04_SPN P04_SPN
label def P04_SPN 98 "98. Spouse not in the household", modify
label values P14A_MOTHERPNR P14A_MOTHERPNR
label def P14A_MOTHERPNR 98 "98. Mother not in the household", modify
label values P15A_FATHERPNR P15A_FATHERPNR
label def P15A_FATHERPNR 98 "98. Father not in the household", modify

The variables used in the dataset are defined as follows:
SN - Household Serial Number
F00_NR- Person number
F02_AGE - Age in completed years
F03_SEX - Sex (1=Male, 2=Female)
P02_RELATION- Relationship to Household head (1-14 defined as above)
P14A_MOTHERPNR - Mother's Person Number (98 means Mother not in the household, missing means Mother dead or respondent does not know her whereabouts)
P15A_FATHERPNR - Father's Person Number (98 means Father not in the household, missing means Father dead or respondent does not know his whereabouts)
P04_SPN - Spouse Person Number (98 means Spouse not in the household)
P03_MARITAL_ST - Marital Status (1=Married, 2=Living together like married partners, 3=Never married, 4=Widower/Widow, 5=Separated 6=Divorced

Thanks in advance for your assistance!

Tatenda

[David Benson]

Hi Tatenda Mugwendere

So I started going through and created a view of the variables / relationships that you mention above. I created lw_father, lw_mother, lw_spouse, lw_children, and lw_sibling. As you know, households can be complicated, and my definitions may not be capturing all of the lw_children and lw_sibling that occur in your data. So, much like I did here, you will want to go through each relationship_type and come up with all the decision rules that capture that relationship.

Also note that I limited siblings to children born to same mother and same father. If the father is not in household (which will often be the case) my code below will not count them as siblings. You'll need to figure out whether you want to call them siblings or half_siblings.

Hopefully this will get you started in the right direction.

* For the 2nd one
egen hhid = group( SN)  // just creating an hhid that goes 1, 2, 3, etc
gen id = _n  // it's useful to have an actual person_id
gen female = ( F03_SEX==2)
gen lw_father = ( P15A_FATHERPNR!=98 & P15A_FATHERPNR!=.)  // lw_ short for "lives with"
gen lw_mother = ( P14A_MOTHERPNR!=98 & P14A_MOTHERPNR!=.)
gen lw_spouse = ( P03_MARITAL_ST==1 & (P04_SPN!=98 & P04_SPN!=.))

* Figuring out siblings
egen has_sibling = total( P02_RELATION==6), by(hhid)  // counts number of siblings in house (siblings of head_of_household)
gen lw_sibling = (P02_RELATION==6)  // by definition they live with sibling if they are sibling of hoh
replace lw_sibling = 1 if P02_RELATION==1 & has_sibling >=1

* Siblings = children of same parents (& parent info not missing)
* I shortened P14A_MOTHERPNR to P14A;  P15A_FATHERPNR to P15A (make sure that will work for your variables)
bysort hhid (P02_RELATION): replace lw_sibling=1 if P02==3 & ((P14A==P14A[_n-1]  & P14A!=98 & P14A!=.) & (P15A==P15A[_n-1]  & P15A!=98 & P15A!=.))
bysort hhid (P02_RELATION): replace lw_sibling=1 if P02==3 & ((P14A==P14A[_n+1]  & P14A!=98 & P14A!=.) & (P15A==P15A[_n+1]  & P15A!=98 & P15A!=.))

egen hh_size = count(F00_NR), by(hhid)  // number of people in household

* Figuring out children
egen children_in_hh = total(P02_RELATION==3), by(hhid)  // count of people listed as "3. Son/daughter"
gen lw_children = 0
replace lw_children = 1 if P02_RELATION==1 & children_in_hh >=1
replace lw_children = 1 if P02_RELATION==2 & children_in_hh >=1
replace lw_children = 1 if P02_RELATION==7  // 7==Parent; If there is a parent in hh, by def there is a child
* P02==7 means person is parent to head of household

* For each hhid, go through each person, and see if that person is listed as parent to someone else in that household
* if P14A== a number (and not 98), then person where F00_NR==that number is a parent (and lw_children should==1)
summ hh_size, meanonly
forvalues i = 1/`r(max)' {
egen parent`i' = total(P14A==`i'), by(hhid)
}

summ hh_size, meanonly
forvalues i = 1/`r(max)' {
bysort hhid : replace lw_children = 1 if parent`i' >=1 & P02_RELATION==`i'
}

* The above loop could've been written as this (but going through 1-6)
bysort hhid : replace lw_children = 1 if parent1 >=1 & P02_RELATION==1
bysort hhid : replace lw_children = 1 if parent2 >=1 & P02_RELATION==2
bysort hhid : replace lw_children = 1 if parent3 >=1 & P02_RELATION==3

. list hhid F00_NR P02_RELATION female lw_father lw_mother lw_spouse lw_sibling lw_children, sepby(hhid) abbrev(12) noobs

  +-------------------------------------------------------------------------------------------------------------------+
  | hhid   F00_NR                P02_RELATION   female   lw_father   lw_mother   lw_spouse   lw_sibling   lw_children |
  |-------------------------------------------------------------------------------------------------------------------|
  |    1        1         1. Head/Acting head        0           0           0           1            0             1 |
  |    1        2     2. Husband/wife/partner        1           0           0           1            0             1 |
  |    1        4             3. Son/daughter        0           1           1           0            1             0 |
  |    1        5             3. Son/daughter        1           1           1           0            1             0 |
  |    1        3             3. Son/daughter        1           1           1           0            1             0 |
  |-------------------------------------------------------------------------------------------------------------------|
  |    2        1         1. Head/Acting head        1           0           0           0            1             1 |
  |    2        3             3. Son/daughter        1           0           0           0            0             0 |
  |    2        5             3. Son/daughter        0           0           0           0            0             0 |
  |    2        4           6. Brother/sister        1           0           0           0            1             0 |
  |    2        6   9. Grand/greatgrand child        0           0           1           0            0             0 |
  |    2        2      14. Non related person        1           0           0           0            0             0 |
  |-------------------------------------------------------------------------------------------------------------------|
  |    3        1         1. Head/Acting head        1           0           1           0            0             1 |
  |    3        2             3. Son/daughter        0           0           1           0            0             1 |
  |    3        3   7. Parent (Mother/father)        1           0           0           0            0             1 |
  |-------------------------------------------------------------------------------------------------------------------|
  |    4        1         1. Head/Acting head        1           0           0           0            0             1 |
  |    4        2             3. Son/daughter        1           0           1           0            0             1 |
  |    4        3             3. Son/daughter        1           0           1           0            0             1 |
  |    4        5   9. Grand/greatgrand child        0           0           1           0            0             0 |
  |    4        4   9. Grand/greatgrand child        1           0           1           0            0             0 |
  |-------------------------------------------------------------------------------------------------------------------|
  |    5        1         1. Head/Acting head        1           0           0           0            0             0 |
  |    5        2   9. Grand/greatgrand child        1           0           0           0            0             0 |
  |    5        3   9. Grand/greatgrand child        0           0           0           0            0             0 |
  |    5        4   9. Grand/greatgrand child        0           0           1           0            0             0 |
  +-------------------------------------------------------------------------------------------------------------------+

[Tatenda Mugwendere]

Wow, This is so good David. It is much clearer now. Thank you so much for your assistance!

Tatenda